изменение LookUp поле на форме

[SHiSHok]

хочу cделать простую модификацию lookup поля для выбора Клиентов- чтоб было 2 поля, но широкие (чтоб все видно было).
Перекрываю метод контрола в дизайне, но не знаю как выставить ширину колонок на гриде.

public void lookup()
{
    SysTableLookup          sysTableLookup = SysTableLookup::newParameters(tableNum(CustTable), this);
    query                   query = new query();
    queryBuildDatasource    qbds;
    ;

    sysTableLookup.addLookupfield(fieldNum(CustTable, AccountNum),true);
    sysTableLookup.addLookupfield(fieldNum(CustTable, Name));

    qbds = query.addDataSource(tablenum(CustTable));
    sysTableLookup.parmQuery(query);
    sysTableLookup.performFormLookup();
}

[MikeR]

Это хочется сделать в одной форме?
Или во всех lookup? Если во всех, то тогда следует изменить свойство displaylength EDT CustAccount, но это приведет к изменению везде в системе, где этот EDT используется

[SHiSHok]

Цитата:

Сообщение от MikeR

Это хочется сделать в одной форме?
Или во всех lookup? Если во всех, то тогда следует изменить свойство displaylength EDT CustAccount, но это приведет к изменению везде в системе, где этот EDT используется

Хочется это сделать только на одной форме, посему особо не хочется менять EDT, изменять AutoLookUp, а также создавать отдельную формочку.

[mazzy]

Цитата:

Сообщение от SHiSHok

Перекрываю метод

(Рыдая...) Не программируйте!!!!
Измените свойство типов как MikeR говорит.

[kashperuk]

Ну, если уж так хотите программировать, копайте в сторону изменения метода buildGrid класса SysTableLookup.
+ нужно добавить параметр ширины в метод addLookupField (а значит и в контейнер lookupItems) и его использовать в методе buildGrid.

Но, ИМХО, это изврат.
Если уж так не хотите менять EDT, создайте просто свою lookupForm и ее вызывайте. Меньше времени потратите

[SHiSHok]

Цитата:

Сообщение от kashperuk

Ну, если уж так хотите программировать, копайте в сторону изменения метода buildGrid класса SysTableLookup.
.....

не надо ничего менять, как я и думал можно за помощью просто к FromRun обратиться и делай чё хотишь

public void lookup()
{
    SysTableLookup          sysTableLookup = SysTableLookup::newParameters(tableNum(CustTable), this);
    query                   query = new query();
    queryBuildDatasource    qbds;
    formRun                 fr;
    FormGridControl         grid;
    ;

    sysTableLookup.addLookupfield(fieldNum(CustTable, AccountNum),true);
    sysTableLookup.addLookupfield(fieldNum(CustTable, Name));


    fr=sysTableLookup.formRun();
    grid = fr.design().controlName("Grid");
    grid.width(512);
    grid.controlNum(1).width(130);
    grid.controlNum(2).width(350);

    qbds = query.addDataSource(tablenum(CustTable));
    sysTableLookup.parmQuery(query);
    this.performFormLookup(fr);
//    sysTableLookup.performFormLookup();
}

[SHiSHok]

Может какой факью по работе с lookup забабахать (а то долго рыл по форуму относительно lookup-ов - много всяких тем)?

[pitersky]

Подниму тему, ибо возникла аналогичная задача.
Предложенный SHiSHok способ очень хороший. Но если нужно ещё и наложить qbr, то операции с FormRun надо опустить в самый низ метода - тогда всё отработает нормально. Т.е. вот так:

public void lookup()
{
.............................
 
    qbds = query.addDataSource(tablenum(CustTable));
// и тут все операции по созданию нужной query
   sysTableLookup.parmQuery(query);
 
    fr=sysTableLookup.formRun();
    grid = fr.design().controlName("Grid");
    grid.width(512);
    grid.controlNum(1).width(130);
    grid.controlNum(2).width(350);
 
     this.performFormLookup(fr);
//    sysTableLookup.performFormLookup();
}

P.S. Да, я знаю, что правильнее менять свойства EDT. К сожалению, это не всегда возможно(((((((((((((

[pitersky]

И ещё один подъём.
На сей раз проблема в следующем. В диалог добавлено по EDT поле со ссылкой на RecId другой таблицы. В лукапе RecId полностью не виден, а растянуть поле в ширину руками нельзя. Как бы его задать автоматом?
Изменение ширины EDT не помогает - меняется размер поля в диалоге, а не в лукапе

[samolalex]

Расширить первое поле грида лукапной формы у меня получилось так:

public void performFormLookup(FormRun _form)
{
    FormGridControl     fgc;
    FormStringControl   fsc;
    ;
    super(_form);

    fgc = _form.design().controlNum(1);
    fsc = fgc.controlNum(1);
    fsc.width(200);
}

[pitersky]

Так не получится. У меня нет формы - только диалог

[samolalex]

диалог в RunBase-классе?

[pitersky]

Цитата:

Сообщение от samolalex

диалог в RunBase-классе?

нет

[samolalex]

В голову пришла следующая мысль - создать диалог, например в джобе, и прикрепить к нему готовую форму, в методе performFormLookup контрола этой формы указать необходимый размер поля лукапного грида, как было приведено мною выше. Данный способ работает, код джобы:

static void TestDialog(Args _args)
{
    dialog                      dialog;
    Object                      o;
    Form                        frm = new Form(formstr(TestForm), false);
    ;

    dialog = new Dialog("Тест", o, "", frm);

    dialog.run();

    if(dialog.closedOk())
    {
    }

}

P.S. На форме диалога нужно будет создать группу DialogStartGrp, плюс ко всему, добавить необходимые контролы (CommandButton'ы и др.).

[S.Kuskov]

не FormRun и не RunBase? Тогда что вы назывете диалогом?

[user_ax]

Да, изврат конечно, но способ с указанием размеров грида помог Lookup нужно было сделать только для одного поля, поэтому, как и в случаях выше, изменение edt не нужно.

public void lookup()
{
    //super();
   SysTableLookup       sysTableLookup       = SysTableLookup::newParameters(tableNum(SalesQuotationLine),this);
    Query                query                = new Query();
    QueryBuildDatasource queryBuildDatasource = query.addDataSource(tableNum(SalesQuotationLine));
    QueryBuildRange queryBuildRange;
    FormRun fr;
    FormGridControl grid;
    ;

    sysTableLookup.addLookupfield(fieldNum(SalesQuotationLine, QuotationId));
    sysTableLookup.addLookupfield(fieldNum(SalesQuotationLine, Name));
    //queryBuildDatasource.addOrderByField(fieldnum(SalesQuotationLine,Name),SortOrder::Descending);
    sysTableLookup.parmQuery(query);
      fr=sysTableLookup.formRun();
    grid = fr.design().controlName("Grid");
   // grid.width(370);
    grid.controlNum(1).width(100);
    grid.controlNum(2).width(270);
    grid.controlNum(1).height(30);
    grid.controlNum(2).height(30);
    this.performFormLookup(fr);
    //sysTableLookup.performFormLookup();
}

Может пригодится кому нибудь)