Помещение временной таблицы в Map - DAX: Программирование

Lemming · 24.10.2008, 10:57

Собственно сабж...Требуется хранить в структуре Map временные таблицы. Просто так ее туда не положить, однако обходной путь вроде бы нашелся. Создал класс обертку

X++:

class TmpTable4CollectionStruct
{
    Common      common;
}
void new(Common     _common)
{
    ;
    //common.setTmp();

    common = _common;
}
Common getCommon()
{
    ;

    return common;
}

И собственно Job-ик для проверки.

X++:

static void Test(Args _args)
{
    LedgerTable                 ledgerTable;
    LedgerTable                 tmpLedgerTable;

    LedgerTable                 tmpLedgerTableFromMap;

    Map                         map = new Map(Types::Integer, Types::Class);

    TmpTable4CollectionStruct   struct,
                                struct2;
    int                         i;
    ;
 

    tmpLedgerTable.setTmp();


    while select ledgerTable
        order by AccountNum
    {
        buf2buf(ledgerTable, tmpLedgerTable);
        tmpLedgerTable.insert();

        i++;

        if (i > 10) break;
    }
    info("Tmp");

    while select tmpLedgerTable
        info(strfmt("%1 -> %2", tmpLedgerTable.AccountNum, tmpLedgerTable.AccountName));

    struct = new TmpTable4CollectionStruct(tmpLedgerTable);



    map.insert(1, struct);

   
    struct2 = map.lookup(1);

    // tmpLedgerTableFromMap.setTmp();
    tmpLedgerTableFromMap = struct2.getCommon();

    info("FromMap");

    while select tmpLedgerTableFromMap
        info(strfmt("%1 -> %2", tmpLedgerTableFromMap.AccountNum, tmpLedgerTableFromMap.AccountName));



}

Вроде бы то, что надо(на практике вся задумка еще не эксплуатировалась), однако хотелось бы узнать, можно ли как-то по другому, без класса обертки помещать собранные временные таблицы в Map!?!

p.s. DAX 4

DSPIC · 24.10.2008, 11:14

можно через контейнер:
buf2Con(Common common),
con2Buf(container c, Common common)

lev · 24.10.2008, 11:14

вот быстренько наваял пример:

X++:

static void test(Args _args)
{
    InventTable     inventTable, inventTableMap;
    Map             map = new Map(Types::Integer, Types::Record);
    MapEnumerator   enumerator;
    ;


    select inventTable
        where inventTable.dm_deleted == NoYes::No;

    map.insert(inventTable.RecId, inventTable);

    enumerator = map.getEnumerator();

    while(enumerator.moveNext())
    {
        inventTableMap = enumerator.currentValue();
    }

    info(inventTableMap.ItemId);
}

Lemming · 24.10.2008, 11:23

Цитата:

Сообщение от lev

вот быстренько наваял пример:

X++:

static void test(Args _args)
{
    ...
    Map             map = new Map(Types::Integer, Types::Record);
    ...


}

Record это одна запись, задача поместить в Map собранную, т.е. содержащую набор записей, временную таблицу.

Yprit · 24.10.2008, 11:27

Цитата:

Сообщение от Lemming

Record это одна запись, задача поместить в Map собранную, т.е. содержащую набор записей, временную таблицу.

Ох... Вот Вы что хотите, оказывается... А зачем? Ну сделайте мэп из мэпов или контейнеров. В мэпы положите нужный вам набор записей.

Yprit · 24.10.2008, 11:18

Цитата:

Сообщение от Lemming

Просто так ее туда не положить

Это, простите, почему?

Lemming · 24.10.2008, 11:20

Цитата:

Сообщение от Yprit

Это, простите, почему?

А как? Можно простенький примерчик!?!

Yprit · 24.10.2008, 11:24

Ну, например, как lev написал. Или вот так

X++:

  Map                 map = new Map(extendedTypeId2Type(typeId(RefRecId)),types::Record);
    TmpFrmVirtual       tmp;
    MapEnumerator       me;
    
    ;
    
    tmp.clear();
    tmp.ItemId = "1";
    tmp.Qty    = 1.00;
    tmp.insert();
    
    tmp.clear();
    tmp.ItemId = "2";
    tmp.Qty    = 2.00;
    tmp.insert();

    tmp.clear();
    tmp.ItemId = "3";
    tmp.Qty    = 3.00;
    tmp.insert();

    while select tmp
        map.insert(tmp.RecId,tmp);
        
    me = map.getEnumerator();
    
    while (me.moveNext())
    {
        tmp = me.currentValue();
        
        info(strFmt("%1 %2",tmp.ItemId,tmp.Qty));
    }

Lemming · 24.10.2008, 11:30

Цитата:

Сообщение от Yprit

Ну, например, как lev написал. Или вот так

X++:

  Map                 map = new Map(extendedTypeId2Type(typeId(RefRecId)),types::Record);
    TmpFrmVirtual       tmp;
    MapEnumerator       me;
    
    ;
    
    tmp.clear();
    tmp.ItemId = "1";
    tmp.Qty    = 1.00;
    tmp.insert();
    
    tmp.clear();
    tmp.ItemId = "2";
    tmp.Qty    = 2.00;
    tmp.insert();

    tmp.clear();
    tmp.ItemId = "3";
    tmp.Qty    = 3.00;
    tmp.insert();

    while select tmp
        map.insert(tmp.RecId,tmp);
        
    me = map.getEnumerator();
    
    while (me.moveNext())
    {
        tmp = me.currentValue();
        
        info(strFmt("%1 %2",tmp.ItemId,tmp.Qty));
    }

То что можно собрать коллекцию Record-ов я знаю, спасибо. Речь идет о том, что например нам необязательно распаковывать класс, что бы положить его в Map, вопрос был как раз в том, можно ли такой фокус провернуть со временной таблой, без лишних оберток. Более того, временные таблицы передаются по ссылке, а не по значению

И хотелось бы как то это свойство сохранить, а вот что будет со ссылкой на орнигинал в случае набора записей(Record-ов) не совсем ясно!?!

kashperuk · 24.10.2008, 16:40

Простите за оффтоп, но это жуткое извращение - временную таблицу в Map, так еще и всю!

EVGL · 24.10.2008, 16:51

Цитата:

Сообщение от kashperuk

Простите за оффтоп, но это жуткое извращение - временную таблицу в Map, так еще и всю!

Отнюдь. Как передать временную таблицу с клиента на сервер или с сервера на клиент? Как сохранить параметры чего-либо в SysLastValue, если параметры организованы во временной таблице?

petr · 24.10.2008, 17:26

Цитата:

Сообщение от EVGL

Как сохранить параметры чего-либо в SysLastValue, если параметры организованы во временной таблице?

А разве просто временная таблица не сохраняется безо всяких Map. Пример - отчет InventDimPhys сохраняет временную таблицу InventDimParm

X++:

final class ReportRun extends ObjectRun
{
    InventDimParm               inventDimParm;

    #define.CurrentVersion(6)
    #localmacro.CurrentList
        ...
        totalAccount,
        inventDimParm
    #endmacro
}
public container pack()
{
    return [#CurrentVersion, #CurrentList] ;
}

EVGL · 24.10.2008, 18:39

Цитата:

Сообщение от petr

А разве просто временная таблица не сохраняется безо всяких Map. Пример - отчет InventDimPhys сохраняет временную таблицу InventDimParm

Да, но это только если там одна запись.

petr · 24.10.2008, 17:32

Цитата:

Сообщение от EVGL

Как передать временную таблицу с клиента на сервер или с сервера на клиент?

Тоже было дело парился с такой задачей. В итоге посмотрел, как это сделано в одном из случаев в стандарте (по-моему при создании кредит ноты или чего-то подобного в заказах) - у наследника runBase перекрыт метод canSwapBetweenCS:

X++:

protected boolean  canSwapBetweenCS()
{
    return false;
}

И все - нет проблемы передачи временной таблицы (из нескольких записей) с сервера на клиент и обратно. (Это как вариант - ни в коем случае не руководство к действию)

Logger · 24.10.2008, 19:59

Цитата:

Сообщение от kashperuk

Простите за оффтоп, но это жуткое извращение - временную таблицу в Map, так еще и всю!

Тем не менее видел такой код при упаковке и распаковке наследников RunBaseBatch в трешке.
Что-то связанное с Supp

Logger · 24.10.2008, 20:00

Цитата:

Сообщение от Lemming

X++:

        buf2buf(ledgerTable, tmpLedgerTable);
        tmpLedgerTable.insert();

Такой код я бы лучше заменил вызовом

X++:

        tmpLedgerTable.data(ledgerTable);
        tmpLedgerTable.insert();

Результат будет тот же, но сэкономит процессорное время.

Lemming · 25.10.2008, 12:41

Цитата:

Сообщение от Logger

Результат будет тот же, но сэкономит процессорное время.

Честно говоря код был написан за 3 минуты для проверки subj-а, но все равно спасибо, буду помнить про data().

**sukhanchik** · 29.10.2008, 21:40

Цитата:

Сообщение от Logger

Такой код я бы лучше заменил вызовом

X++:

        tmpLedgerTable.data(ledgerTable);
        tmpLedgerTable.insert();

Результат будет тот же, но сэкономит процессорное время.

В отличии от метода buf2buf - метод data имеет две особенности, о которых нужно помнить при его использовании:
1. При необходимости программно скопировать запись в постоянной таблице - данный метод просто спозиционирует переменную таблицы на ту же запись - т.е следующая конструкция только "откопирует" курсор, при этом RecId не будет равен нулю (что логично, но не всегда удобно):

X++:

    LedgerTable fromLedgerTable, toLedgerTable;
    ;
    select fromLedgerTable;
    toLedgerTable.data(fromLedgerTable);

2. Метод data (в отличии от buf2buf) копирует все системные поля. Но если поля modified* и RecId все равно перезапишутся при вызове метода insert(), то остальные поля к примеру create* и dataAreaId не перезапишутся. Таким образом следующий код приведет к созданию записи не в той компании:

X++:

    LedgerTable fromLedgerTable, toLedgerTable;
    ;
    changecompany ('dax')
    {
        select fromLedgerTable;
        changecompany ('nav')
        {
            toLedgerTable.data(fromLedgerTable);
            toLedgerTable.insert(); // Будет создана запись в компании dax
        }
    }

не говоря уже о том, что данные в полях create* будут некорректными. Тот же эффект будет наблюдаться и при использовании временных таблиц.

Turganov Artem · 20.04.2009, 00:01

Пришлось реализовать задачу с временной таблицей в Map.
В контейнер и Map можно сохранить только Record. Копия строки в таблице, но не само строку (обновить ее нельзя, если извлечь из Маp, сначала ее надо найти в таблице).
Без обертки не как, кроме класса можно использовать класс формы.
Пакуем очевидно класс - обертку.

Лично пришлось решать как обычно не стандартную задачу. На каждом этапе сложно алгоритма нужно было сохранять промежуточную таблицу. Создаю класс с временной таблице - пишу на каждом этапе. На выходе меню со списком этапов. Кнопка по текущему курсору открывает форму с нужны экземпляром сохраненной темповой таблицы со контентом из Map.

konfet · 19.10.2017, 11:58

X++:

static void msk_testStruct(Args _args)
{
    struct val;
    Map map = new map(Types::Integer, Types::Class);
    MapEnumerator enum;
    int i;

    struct setCar(int modelYear, str Carbrand)
    {
        struct myCar;
        ;
        
        myCar = new struct ("int ModelYear; str Carbrand");
        mycar.value ("ModelYear", modelYear);
        mycar.value ("Carbrand", carbrand);
        return mycar;
    }
    ;

    map.insert(1, setCar(2000, "BMW"));
    map.insert(2, setCar(2005, "Mersedes"));

    enum = map.getEnumerator();
    while (enum.moveNext())
    {
        i = enum.currentKey();
        val = enum.currentValue();
        info(strFmt("N = %1, Year = %2, Brand = %3", i, val.value("ModelYear"), val.value("Carbrand")));
    }
}

Похожие темы
Тема	Автор	Раздел	Ответов	Посл. сообщение
Динамическое связывание временной таблицы	Paul_ST	DAX: Программирование	8	25.09.2007 16:17
данные из временной таблицы в отчете	алька	DAX: Программирование	4	19.04.2007 17:47
Проблема с очисткой временной таблицы	v.fedorov	DAX: Программирование	13	26.10.2006 23:02
Формирование отчета на основе временной таблицы	neys	DAX: Программирование	8	26.05.2006 15:23
Получение из поля Map кода поля реальной таблицы, к ней привязанной (Mappings)	vey	DAX: Функционал	5	16.03.2005 11:16

Опции темы	Поиск в этой теме
Версия для печати Отправить по электронной почте	Поиск в этой теме: Расширенный поиск
Опции просмотра
Линейный вид Комбинированный вид Древовидный вид