Финансовые аналитики

[jiller]

Добрый день!
У меня вопрос, подскажите пожалуйста кто знает: как программно получить список финансовых аналитик, а точнее их названия?

P.S. DAX 4.0 SP2

[Jox]

while select Dimensions {...}

[lev]

если речь идёт просто о том какие фин аналитики есть в системе, то можно вот так:

    SysDictEnum dictEnum = new SysDictEnum(enumnum(SysDimension));
    int         i, cnt, iSearch;
    ;

    cnt = dictEnum.lastValue();

    for(i=dictEnum.firstValue(); iSearch <= cnt; i = dictEnum.nextValue(i))
    {
        iSearch++;
        info(dictEnum.value2Label(i));
    }

[jiller]

Цитата:

Сообщение от lev

если речь идёт просто о том какие фин аналитики есть в системе, то можно вот так:

    SysDictEnum dictEnum = new SysDictEnum(enumnum(SysDimension));
    int         i, cnt, iSearch;
    ;

    cnt = dictEnum.lastValue();

    for(i=dictEnum.firstValue(); iSearch <= cnt; i = dictEnum.nextValue(i))
    {
        iSearch++;
        info(dictEnum.value2Label(i));
    }

Спасибо! Это как раз и надо было.

[petergunn]

Цитата:

Сообщение от lev

если речь идёт просто о том какие фин аналитики есть в системе, то можно вот так:

    SysDictEnum dictEnum = new SysDictEnum(enumnum(SysDimension));
    int         i, cnt, iSearch;
    ;

    cnt = dictEnum.lastValue();

    for(i=dictEnum.firstValue(); iSearch <= cnt; i = dictEnum.nextValue(i))
    {
        iSearch++;
        info(dictEnum.value2Label(i));
    }

Приведенный алгоритм содержит потенциальный bug

Мастером финансовых аналитик (или просто в AOT) добавляем новый элемент со значением 101 (т.е. не последовательно 0,1,2,3,4,...) в enum SysDimension - в итоге цикл начинает отрабатывать 102 итерации т.к. сравнение идет iSearch <= 101 начиная с 0.

Если необходим список активных значений, то дополнительно можно проверить на предмет активности конфигурационного ключа на значении enum'а, что-то в таком духе:

static void jbDimensionListByEnum(Args _args)
{
    DictEnum    dictEnum = new DictEnum( enumNum( SysDimension ) ) ;
    Counter     enumIdx ;
    
    #define.OnlyActive
    ;

    for( enumIdx = 0; enumIdx < dictEnum.values(); enumIdx++ )
    {
#if.OnlyActive
        if( !isConfigurationKeyEnabled( dictEnum.index2ConfigurationKey( enumIdx ) ) )
            continue ;
#endif
        info( dictEnum.index2Label(enumIdx));
    }
}

[jiller]

И еще такой вопрос: как получить информацию о EDT, используемых в массиве типа Dimension?

[lev]

Цитата:

Сообщение от petergunn

Приведенный алгоритм содержит потенциальный bug

Согласен.
Просто в разрезе описанной задачи посчитал, что такого кода достаточно, т.к. сомневаюсь что в финансовых аналитиках, кто то добавит элемент со значением 101.

[jiller]

Всем огромное спасибо за помощь!

[Eldar9x]

Еще более короткий вариант, тут вообще ничего проверять не надо

    int c;
    ;
    for (c = 1; c <= new DictType(extendedtypenum(Dimension)).arraySize(); c++)
        info(new DictType(extendedtypenum(Dimension)).label(c));

Можете соптимизировать, дабы один и тот же объект два раза не создавать.
Отвечая на последний вопрос, new DictType(extendedtypenum(Dimension)) вам в помощь, там большинство методов этого объекта требуют указания индекса элемента.

[petr]

Просто раз уж тему открыл, то предложу и свое решение задачи:

static void Job2(Args _args)
{
    SetEnumerator   dimensionsEnumerator = Dimensions::dimensionCodesSet().getEnumerator();
    SysDimension    sysDimension;
    ;

    while (dimensionsEnumerator.moveNext())
    {
        sysDimension = dimensionsEnumerator.current();
        print enum2str(sysDimension);
    }
    
    pause;
}

[gefr]

У меня есть расширение этой задачи - добавление на форму "отвязанных" контролов по фин. аналитикам. Вариант с добавлением всех и последующим скрытием не интересен, т.к. заранее не известно, сколько аналитик будет.
Делаю так:

        DictEnum DictEnum = new DictEnum(enumnum(SysDimension));
        FormBuildDesign             formBuilddesign = form.design();
        FormBuildGroupControl       formBuildGroupControl;
        FormStringControl c;
        int      i;

        ;

        if (dictEnum){
            for (i=0; i<dictEnum.values(); i++){
            c = DimensionList.addControl(FormControlType::String,strfmt("_%1",dictEnum.index2Symbol(i)));
            c.extendedDataType(global::extendedTypeName2Id(strfmt("Dimension[%1]",i)));
            c.showLabel(true);
            c.label(dictEnum.index2Name(i));
            c.lookupButton(2);
            }
        }

Элементы появляются, но выпадающие списки не работают, т.е. тип не подцепляется. Не делать showlabel, label и lookupbutton пробовал, получается простое текстовое поле, что еще раз подтверждает, что тип не подхватывается.
Не подскажете, в чем дело?

[S.Kuskov]

Цитата:

Сообщение от gefr

У меня есть расширение этой задачи - добавление на форму "отвязанных" контролов по фин. аналитикам.
...
выпадающие списки не работают, т.е. тип не подцепляется

А вы попробуйте для начала решить задачу не программно а в ручную. Получится?
Когда будете создавать unbound контрол вручную какой расширенный тип выберете?
Что, по-вашему, должен вернуть метод global::extendedTypeName2Id(strfmt("Dimension[%1]",i))?

[sukhanchik]

Цитата:

Сообщение от gefr

У меня есть расширение этой задачи - добавление на форму "отвязанных" контролов по фин. аналитикам.
...
Не подскажете, в чем дело?

В свое время для 4.0 пытался также решать похожую задачу и не тоже смог победить. Причем - такой вариант, как задание строкового типа Dimension[i] не катит - это точно - нет такого типа в системе.

Нашел для себя 2 "обходных" пути.
1. Для диалогов - наследников RunBase есть класс DialogAddDimensionType_CheckButton_RU. Он добавляет в диалог флажки, по количеству элементов в массиве в типе Dimension. По сути здесь простой цикл и все. Но это решает задачу добавления именно "отвязанных" контролов. Важно! Здесь список контролов подготавливается ДО init формы. Т.к. после - уже не получается (ну у меня тогда не получилось). При этом лукапы для каждого элемента массива тут работать не будут (если пытаться заменить галки на строковые поля). Т.е. если хочется добавить контрол с лукапом в случае массива - он должен быть "связанным"

2. Если нужно сделать лукап со списком полей (а может и лукап со списком значений) аналогично форме расширенного запроса (SysQueryForm) - то нужно использовать класс SysQueryForm (его можно использовать, предварительно подготовив всякие таблички и Query). При этом, обращаю внимание - там используется табличка TmpSysQuery и у контрола типа Dimension проставлен не EDT, а FieldId, причем свойство ArraySize не используется (оно не работает), а в FieldId подставлено значение fieldId2Ext(fieldnum(Dimension), i), где i - индекс массива. Здесь видно, что лукап у поля "Значения" строится в зависимости от выбранного элемента массива.

[gefr]

2 S.Kuskov: да, вы правы, тупанул переделал так - все равно не помогло.

                c.extendedDataType(typeid(Dimension));
                c.arrayIndex(i);

[sukhanchik]

Цитата:

Сообщение от gefr

2 S.Kuskov: да, вы правы, тупанул переделал так - все равно не помогло.

                c.extendedDataType(typeid(Dimension));
                c.arrayIndex(i);

Я ж сказал - не работает это свойство. Ошибся в названии - не ArraySize, а arrayIndex

[S.Kuskov]

Цитата:

Сообщение от sukhanchik

Я ж сказал - не работает это свойство. Ошибся в названии - не ArraySize, а arrayIndex

Сейчас попробовал. В AX2009 arrayIndex как минимум влияет на Label

Вот тут ещё было обсуждение этой проблемы Статьи аналитик

[gefr]

Там, к сожалению, про диалоги. В диалогах проблем нет, я это и так знал, сразу попробовал и здесь, на форме. На форме не срастается

[Wamr]

public void init()
{
    FormBuildDesign             formBuilddesign = form.design();
    FormBuildGroupControl       formBuildGroupControl = form.design().control('AddGroup');
    formBuildStringControl      bc;
    ;

    bc = formBuildGroupControl.addControl(FormControlType::STRING,'RunTimeControl');
    bc.extendedDataType(typeId2ExtendedTypeId(typeId(Dimension)));
    bc.arrayIndex(2);

    super();
}

[gefr]

К сожалению, не могу добавить благодарность 2Wamr - сайт артачится. Но все равно - спасибо.