Отчёт в файл

[ZVV]

Привет всем.

Вполне возможно, что вопрос ламерски лёгкий, но как-то так исторически сложилось, что с отчётами и принтерами я не дружу и с ними практически не работаю.

Есть необходимость при разноске счёта на оплату по заказу на продажу сформировать отчёт в файл. Всё это можно сделать руками (Разноска - счёт на оплату - печать счёта на оплату - настройки печати - в файл), но мне это нужно сделать прямо в коде без всякого интерактива. Не хочется долго ковыряться в этих printerSetting-ах. Может кто-то подскажет примерный код, как это сделать? Или хотя бы носом ткнёт в подобный код, если такой есть в АОТ. Интересуют только настройки принтера для FormLetter. С самой разноской проблем не предвидится...

Спасибо.

[SRF]

Посмотрите здесь(возможно то, что нужно)
create Pdf invoice report

[ZVV]

Цитата:

Сообщение от SRF

Посмотрите здесь(возможно то, что нужно)
create Pdf invoice report

Действительно, всё получилось. (правда не знаю, что там не получилось у автора того сообщения, он подробностей не сообщал...)

Вот такой код работает на ура:

    SalesId salesId = 'ля-ля-ля';
    PrintJobSettings    PrintJobSettings;
    salesFormLetter salesFormLetter;
    ;

    salesFormLetter = SalesFormLetter::construct(DocumentStatus::Invoice4Paym_RU);

    salesFormLetter.printFormLetter(true);

    printJobSettings = new PrintJobSettings(salesFormLetter.printerSettingsFormletter());
    printJobSettings.setTarget(PrintMedium::File);
    printJobSettings.format(PrintFormat::ASCII);
    printJobSettings.fileName("C:\\Test_Order.txt");
    salesFormLetter.updatePrinterSettingsFormLetter(printJobSettings.packPrintJobSettings());

    salesFormLetter.update(salesTable::find(salesid), systemDateGet(), SalesUpdate::All);

Правда прежде, чем всё стало окей, намучался с таким сообщением при печати:

Цитата:

Параметры управления печатью не могут быть применены, поэтому не получено ни одного документа.
Отчет не содержит данных, Счет на оплату - Отчет

Счёт на оплату разносился, строки в нём есть - а отчёт так ругался и не печатался (в смысле не сохранялся в файл). Причём не на всех, а только на части заказов... :-\
После ковыряний и разборок по коду выяснилось, что причина в Настройки - Управление печати в Клиенте. Нужно там создать запись (в таблице PrintMgmtDocInstance). Может, конечно, это и так все знают , но мне было не очевидно - потратил много времени. Мот кому пригодится...

DAX 2009

[ZVV]

Ещё, кстати, можно сделать вот так... Это для того что бы файлик назвать "нужным" именем.

{
    SalesId                 salesId = 'ля-ля-ля';
    PrintJobSettings    PrintJobSettings;
    salesFormLetter       salesFormLetter;
    CustInvoice4PaymJour_RU            common;
    ;

    salesFormLetter = SalesFormLetter::construct(DocumentStatus::Invoice4Paym_RU);

    salesFormLetter.update(salesTable::find(salesid), systemDateGet(), SalesUpdate::All);
    common = salesFormLetter.journal();

    salesFormLetter.printFormLetter(true);
    printJobSettings = new PrintJobSettings(salesFormLetter.printerSettingsFormletter());
    printJobSettings.setTarget(PrintMedium::File);
    printJobSettings.format(PrintFormat::ASCII);
    printJobSettings.fileName("C:\\" + common.Invoice4PaymId + ".txt");
    salesFormLetter.updatePrinterSettingsFormLetter(printJobSettings.packPrintJobSettings());
    salesFormLetter.printJournal();
}

[ZVV]

Цитата:

Сообщение от ZVV

...
После ковыряний и разборок по коду выяснилось, что причина в Настройки - Управление печати в Клиенте. Нужно там создать запись (в таблице PrintMgmtDocInstance).
...

Добрые люди подсказали что есть настройки по умолчанию для всех
РсК \ Настройка \ Формы \ Настройка форм \ Управление печатью

[belugin]

http://erpkb.com/Axapta/VstroennyeOtchety#h18498-2

[ZVV]

Цитата:

Сообщение от belugin

http://erpkb.com/Axapta/VstroennyeOtchety#h18498-2

Способ хороший, жаль тока вот для счёта на оплату (русского, самобытного ) в чистом виде не подходит, т.к. отчёт SalesPurchInvoice4Paym_RU имеет следующий инит:

void  init()
{
    if (! element.args() ||
        ! element.args().caller() ||
        (classidget(element.args().caller()) != classnum(SalesReport_Invoice4Paym_RU) &&
         classidget(element.args().caller()) != classnum(PurchReport_Invoice4Paym_RU)))
        throw error("@SYS32665");

    salesPurchReport = element.args().caller();
    languageId = CompanyInfo::languageId();
    converter   = RNumDateInWordConverter::construct(languageId);
    super();
}

Так что тут надо было бы через класс SalesReport_Invoice4Paym_RU делать примерно то же самое... Но я предпочёл другой способ.