QueryBuildRange в select.. where

[propeller]

Имеется:
qbr = qbd.addRange(fieldNum(LedgerJournalTrans, TransDate));

как в select добавить условие из range:
while select AvLedgerJournalTrans
where AvLedgerJournalTrans.TransDate == qbr ??

возможно ли такое?

[lev]

while select AvLedgerJournalTrans
where AvLedgerJournalTrans.TransDate == qbr.value();

только этот range в начале заполниться должен гдето (или пользователем или в коде).
чтобы найти этот range в запросе нужно использовать метод findRange() у QueryBuildDataSource.

[propeller]

пробовал так, при компиляции " типы операнда не совместимы с оператором" .
да, заполняется пользователем.
у меня 2.5 Акс. может она что-то не понимает)

[lev]

вот написал джоб естественно типы сравниваемых полей должны совпадать!

static void test(Args _args)
{
    Query                   query = new Query();
    QueryBuildDataSource    qbds;
    QueryBuildRange         qbr;
    InventTable             inventTable;
    ;
    // создаем запрос
    qbds = query.addDataSource(tableNum(InventTable));
    qbds.addRange(fieldNum(InventTable, ItemId)).value('Номенклатура');

    // ищем в запросе range
    qbr = qbds.findRange(fieldNum(InventTable, ItemId));

    // используем в запросе
    select InventTable
        where inventTable.ItemId == qbr.value();
}

всё нармально отрабатывает без всяких ругательств

[lev]

чтобы быть уверенным в том что сходятся типы полей, можно сделать через переменную:

static void test(Args _args)
{
    Query                   query = new Query();
    QueryBuildDataSource    qbds;
    QueryBuildRange         qbr;
    InventTable             inventTable;
    ItemId                  itemId;
    ;
    // создаем запрос
    qbds = query.addDataSource(tableNum(InventTable));
    qbds.addRange(fieldNum(InventTable, ItemId)).value('Номенклатура');

    // ищем в запросе range
    qbr     = qbds.findRange(fieldNum(InventTable, ItemId));
    itemId  = qbr.value();// используем переменную

    // используем в запросе
    select InventTable
        where inventTable.ItemId == itemId;
}

[Lemming]

Цитата:

Сообщение от lev

while select AvLedgerJournalTrans
where AvLedgerJournalTrans.TransDate == qbr.value();

Хочется напомнить, что метод value класса QueryBuildRange имеет тип String, так что если такой "финт" и получится сделать, то исключительно с текстовыми полями. Поэтому автор вопроса сходу получил ошибку:

Цитата:

Сообщение от propeller

пробовал так, при компиляции " типы операнда не совместимы с оператором" .

В любом случае, ИМХО, подход кривой, propeller, Вы бы рассказали зачем Вам это понадобилось?

[lev]

Цитата:

Сообщение от Lemming

Хочется напомнить, что метод value класса QueryBuildRange имеет тип String, так что если такой "финт" и получится сделать, то исключительно с текстовыми полями.

Точно, никогда не обращал внимания Спасибо Lemming.

[Gustav]

Цитата:

Сообщение от Lemming

В любом случае, ИМХО, подход кривой, propeller, Вы бы рассказали зачем Вам это понадобилось?

наверняка хотим что-то такое сделать:

qr = new QueryRun(..._ds.queryRun().query());
while(qr.next())
{
    // что-то делаем с каждой записью из отфильтрованного пользователем набора
}

[propeller]

в квери у меня один запрос по 2 таблицам с группорвками,
селектом нужно было сделать подобный запрос но еще +2 таблицы джоином, а потом уже группировки.
Хорошо если нельзя селектом, сделал второй query,
написал в нем:
qbr2.value(qbr1.value()) - не работает
написал qbr2 = qbr1 тоже не работает, ну я думаю так и не должно.
как правильно тогда передать из одного query1 рендж в другой query2?

[Bishop]

Все это будет работать только в случае точного указания искомого значения в range.
В общем случае (range.value("A, B, C..D, !E, F*, *G, *H*")) проблема с добавлением в select условий из Query неразрешима.

[Russland]

Цитата:

как правильно тогда передать из одного query1 рендж в другой query2?

Попробуйте поджойнить ваши квери

[lev]

Что то типа такого:

static void test(Args _args)
{
    Query                   query = new Query();
    QueryRun                queryRun;
    QueryBuildDataSource    qbds, qbds1, qbdsJoin;
    ;
    // первый запрос
    qbds = query.addDataSource(tableNum(InventTable));
    qbds.addRange(fieldNum(InventTable, ItemId)).value('Номенклатура');

    queryRun = new QueryRun(query);
    // джойним ещё таблицу
    qbds1 = queryRun.query().dataSourceTable(tableNum(InventTable));

    qbdsJoin = qbds1.addDataSource(tablenum(InventItemGroup));
    qbdsJoin.relations(true);
    qbdsJoin.addRange(fieldNum(InventItemGroup, ItemGroupId)).value(QueryValue('Группа'));
}