Помогите с Query

[Vitali_i]

Всем доброго дня.
Подскажите, как реализовать в DAX следующий sql запрос, желательно через Query.
Запрос нужен для суммирования пересчитанных данных.

select a.tovar, sum(a.kolichestvo * b.percent)
from table1 a, table2 b
where a.field_a = b.field_b
group by a.tovar

Или убрать (крайне нежелательно) из запроса функцию sum и просуммировать после выполнения, используя цикл ?

while (QueryRun.next())

[miklenew]

Никак.
Используйте while select.
Он быстрее чем QueryRun.

[Vitali_i]

Спасибо, за оперативный ответ.

Жаль, что нет такого функционала.

[miklenew]

НЗ.
Можно через ODBC, ADO, но представлете что будет если в аксе начать заменять while select на доступ к базе миную аксу. Бардак будет.

[_scorp_]

Цитата:

Сообщение от miklenew

Используйте while select.
Он быстрее чем QueryRun.

А можно поподробнее?

[miklenew]

Цитата:

Сообщение от _scorp_

А можно поподробнее?

Можно

    xRefNames xRefNames;
    int       start;
    int       end;
;
    start = timenow();
    while select xRefNames
    {

    }
    end = timenow();
    info("while " + time2str(end-start,1,1));

и

    xRefNames xRefNames;
    int       start;
    int       end;
    QueryRun  queryRun;
    query     query;
;
    start = timenow();
    query = new Query();
    query.addDataSource(tablenum(xRefNames));

    queryRun = new QueryRun(query);

    while (queryRun.next())
    {
        xRefNames = queryRun.get(TableNum(xRefNames));
    }
    end = timenow();
    info("queryRun " + time2str(end-start,1,1));

У меня получилось 28 и 46 секунд соответственно.

[_scorp_]

Цитата:

Сообщение от miklenew

У меня получилось 28 и 46 секунд соответственно.

Тестировал в AX 2009. Запускал job 2 раза. У меня получился примерно тот же порядок - while select быстрее queryRun на 50%...

static void JobQR(Args _args)
{
    LedgerTrans ledgerTrans;
    AccountNum  accountNum;
    int         start;
    int         end;
    
    void queryWhileSelect()
    {
        while select ledgerTrans
        {
            accountNum = ledgerTrans.AccountNum;
        }
    }
    
    void queryQueryRun()
    {
        Query       q;
        QueryRun    qr;
        LedgerTrans ledgerTransLocal;
        ;
        q = new Query();
        q.addDataSource(tablenum(LedgerTrans));
        qr = new QueryRun(q);
        while (qr.next())
        {
            ledgerTransLocal = qr.get(tablenum(LedgerTrans));
            accountNum = ledgerTransLocal.AccountNum;
        }
    }
    ;
    
    start = timenow();
    queryWhileSelect();
    end = timenow();
    info("while " + time2str(end-start,1,1));
    
    start = timenow();
    queryQueryRun();
    end = timenow();
    info("queryRun " + time2str(end-start,1,1));
}

[S.Kuskov]

A сравнивали с

while select * from Table {}

или

while select Table {}

?

Ага увидел. Попробуйте со звёздочкой для, чистоты эксперимента.

[S.Kuskov]

У меня

while select * from Table {}

выполняется долше чем

while select Table {}

Причём время выпонения становится сопоставимо с временем работы QueryRun.

Возможно на результаты иследования скорости повлиял оптимизатор. ИМХО while select при прочих равных не должен быть быстрее QueryRun.

P.S.: Кстати показательный пример в пользу активного использования SelectionField:: Database

[miklenew]

Цитата:

Сообщение от S.Kuskov

ИМХО while select при прочих равных не должен быть быстрее QueryRun.

Если сможете получить такой результат напишите.

[tricky]

В Axapta 3.0 получились примерно схожие результаты. Правда пробовал на другой таблице, но, думаю, это погоды не делает. "QueryRun" - 43 сек, а "while select" - 42 сек.

[S.Kuskov]

Мои результаты

static void JobTestSpeed(Args _args)
{
    int i;
    
    void t1()
    {
        RContractTable RContractTable;
        int       start;
        int       end;
        ;
 
        start = timenow();
        while select * from RContractTable {}
        end = timenow();
        info("while " + time2str(end-start,1,1));
    }
    
    void t2()
    {
        RContractTable RContractTable;
        int       start;
        int       end;
        QueryRun  queryRun;
        query     query;
        ;
        
        start = timenow();
        query = new Query();
        query.addDataSource(tablenum(RContractTable));

        queryRun = new QueryRun(query);

        while (queryRun.next())
        {
            RContractTable = queryRun.get(TableNum(RContractTable));
        }
        end = timenow();
        info("queryRun " + time2str(end-start,1,1));
    }
    ;
    
    info(int642str((select count(RecId) from RContractTable).RecId));
    
    for (i = 1; i <= 5; i++) t1();
    for (i = 1; i <= 5; i++) t2();
    for (i = 1; i <= 5; i++) {t1();t2();}
}

Цитата:

21291
while 00:00:35
while 00:00:32
while 00:00:36
while 00:00:36
while 00:00:33
queryRun 00:00:36
queryRun 00:00:35
queryRun 00:00:38
queryRun 00:00:37
queryRun 00:00:40
while 00:00:36
queryRun 00:00:38
while 00:00:37
queryRun 00:00:35
while 00:00:36
queryRun 00:00:34
while 00:00:32
queryRun 00:00:34
while 00:00:34
queryRun 00:00:34

Тестировал на живой базе. Так-что разброс есть, но в обе стороны и не 50%

[_scorp_]

Цитата:

Сообщение от S.Kuskov

Мои результаты

Какая версия AX?

[S.Kuskov]

Пардон.

AX4.0SP2
Kernel version: 4.0.2163.0
Application version: 4.0.2501.347

[miklenew]

Цитата:

Сообщение от S.Kuskov

Тестировал на живой базе. Так-что разброс есть, но в обе стороны и не 50%

Вот мои результаты по вашему job. Только таблицу поменял на xRefNames

Цитата:

Сообщение (10:29:13)
312573
while 00:00:13
while 00:00:14
while 00:00:14
while 00:00:13
while 00:00:12
queryRun 00:00:22
queryRun 00:00:21
queryRun 00:00:22
queryRun 00:00:20
queryRun 00:00:21
while 00:00:13
queryRun 00:00:20
while 00:00:13
queryRun 00:00:20
while 00:00:13
queryRun 00:00:20
while 00:00:13
queryRun 00:00:20
while 00:00:13
queryRun 00:00:20

AX4.0
Kernel version: 4.0.2163.0
Application version: 4.0.2163.0
А база у вас чья? Oracle или MS SQL?
Я пробовал на MS SQL 2005.

[DSPIC]

А не сравнивали запросы, уходящие на SQL в обоих случаях (while, queryRun)? Было бы любопытно на них взглянуть

[S.Kuskov]

Ага. Это поля индекса. Причём даже если индекс не PrimaryIndex и не ClusterIndex в Query всё равно добаляется сортировка по нему. Явный .sortClear() тоже не убирает order by из запроса.

Может есть какя-нибудь настройка AOS, которую можно выключить? Конечно очень странное решение - по умолчанию навязывать сортировку во всех Query.

[ZVV]

Цитата:

Сообщение от S.Kuskov

Ага. Это поля индекса. Причём даже если индекс не PrimaryIndex и не ClusterIndex в Query всё равно добаляется сортировка по нему. Явный .sortClear() тоже не убирает order by из запроса.

Может есть какя-нибудь настройка AOS, которую можно выключить? Конечно очень странное решение - по умолчанию навязывать сортировку во всех Query.

Не то слово - "странное"... И оно во всех формах присутствует.
И убрать это вроде как нельзя никак - по крайней мере так мне сказал представитель майкрософта в приватной беседе на прошлом мастер-классе по 4-ке.

[in.dc]

Цитата:

Сообщение от ZVV

Цитата:

Сообщение от S.Kuskov

Ага. Это поля индекса. Причём даже если индекс не PrimaryIndex и не ClusterIndex в Query всё равно добаляется сортировка по нему. Явный .sortClear() тоже не убирает order by из запроса.

Может есть какя-нибудь настройка AOS, которую можно выключить? Конечно очень странное решение - по умолчанию навязывать сортировку во всех Query.

Не то слово - "странное"... И оно во всех формах присутствует.
И убрать это вроде как нельзя никак - по крайней мере так мне сказал представитель майкрософта в приватной беседе на прошлом мастер-классе по 4-ке.

сдается мне, что слукавил 'представитель майкрософта' в этом вопросе, и убрать явную сортировку в общем то возможно.

Сортировка в QueryRun навязывается механизмом Record Level Security (который для этих объектов по умолчанию включен, состояние флага RLS QueryRun первоначально наследуется из Query на основе которого создается), если при инициализации этих объектов явно отключить RLS ( Query.recordLevelSecurity( false ) или QueryRun.recordLevelSecurity( false ) ) то запрос уже не будет содержать ORDER BY по полям индекса:

QueryRun.recordLevelSecurity( false ):

...
FROM LEDGERTRANS A WHERE (DATAAREAID=?)

QueryRun.recordLevelSecurity( true ):

FROM LEDGERTRANS A WHERE (DATAAREAID=?) ORDER BY A.DATAAREAID,A.ACCOUNTNUM,A.TRANSDATE,A.VOUCHER,A.AMOUNTMST

P.S. тестировалось на SQL2005

[ZVV]

Цитата:

Сообщение от in.dc

сдается мне, что слукавил 'представитель майкрософта' в этом вопросе, и убрать явную сортировку в общем то возможно.

Ну мы с ним про формы говорили, а не про Query, так что может и не слукавил таки...

Да и отключать RLS в запросах тоже не всегда представляется возможным...

ЗЫ Хотя всё равно я не понял, зачем этот ордер бай нужен, при RLS...