проблема с перекрытием lookupreference в dialog

[Pandasama]

Товарищи, начинаю активно работать в 2012 и встречаюсь с некоторыми проблемами.
В данный момент проблема следующая:
есть класс (наследник RunBase), в классе диалог, в диалоге следующее:

protected Object dialog()
{
    Dialog                  dialog = super();
    Object                  formCtrl;
    ;

    dlgAgreementClassification = dialog.addFieldValue(extendedTypeStr(agreementClassificationRecId), agreementClassificationRecId, "Выберите новую классификацию");
    //formCtrl = dlgAgreementClassification.control();
    //formCtrl.replacementFieldGroup(identifierStr(AutoIdentification));
    //formCtrl.registerOverrideMethod(identifierStr(lookupReference), tableMethodStr(AgreementHeader, lookupReferenceAgreementClassification), this);
    dlgAgreementClassification.registerOverrideMethod(identifierStr(lookupReference), tableMethodStr(AgreementHeader, lookupReferenceAgreementClassification), this);

    return dialog;
}

метод AgreementHeader::lookupReferenceAgreementClassification, соответственно следующий

public Common lookupReferenceAgreementClassification(FormReferenceControl _formReferenceControl)
{
    AgreementHeaderExt_RU   agreementHeaderExt;
    Query query = new Query();
    QueryBuildDataSource qbds;
    QueryBuildDataSource QbdsJoin;
    SysReferenceTableLookup sysTableLookup = SysReferenceTableLookup::newParameters(tableNum(AgreementClassification), _formReferenceControl)
    ;
    qbds = query.addDataSource(tableNum(AgreementClassification));
    switch (agreementHeaderExt.AgreementType)
    {
        case AgreementType::Contract:
            qbds.addRange(fieldNum(AgreementClassification, MainAgreement)).value(queryValue(NoYes::Yes));
            break;
        case AgreementType::AdditionalAgreement:
            qbds.addRange(fieldNum(AgreementClassification, MainAgreement)).value(queryValue(NoYes::Yes));
            break;
    }
    qbds.addRange(fieldnum(AgreementClassification, AgreementRelationType)).value(queryValue(this.InstanceRelationType));

    sysTableLookup.parmQuery(query);
    sysTableLookup.addLookupfield(fieldNum(AgreementClassification, Name));
    sysTableLookup.addLookupfield(fieldNum(AgreementClassification, Description_PSN));
    return sysTableLookup.performFormLookup();
}

в другом месте, на статичной форме, этот lookupreference работает нормально
запустив же класс и в его диалоге попробовав сделать лукап - получаю ошибку

Ошибка времени выполнения: FormReferenceGroupControl (Объект), метод lookupReference вызван с недопустимыми параметрами.

Трассировка стека

(C)\Classes\FormReferenceGroupControl\lookupReference
(C)\Classes\FormReferenceGroupControl\Lookup
(C)\Classes\FormStringControl\Lookup

пошерстив АОТ на предмет классов с методом диалог и registerOverrideMethod нашел ряд стандартных примеров, и кардинальных отличий от своего кода не увидел

что я делаю не так?

[AndyD]

Так в сигнатуре метода lookupReference() никаких параметров нет

Да и вообще, странно как-то.
Вы регистрируете метод, как принадлежащий классу, но на самом деле он находится в таблице
Или у вас в классе дублируется метод lookupReferenceAgreementClassification?

[Pandasama]

А что, registerOverrideMethod можно делать только на метод класса?
Нет, метод lookupReferenceAgreementClassification только в таблице, поэтому, соответственно, там и tableMethodStr использую

[TasmanianDevil]

Цитата:

Сообщение от Pandasama

А что, registerOverrideMethod можно делать только на метод класса?

dlgAgreementClassification.registerOverrideMethod(identifierStr(lookupReference), tableMethodStr(AgreementHeader, lookupReferenceAgreementClassification), this);

Переопределяем что, чем и и где живет это "чем".

На this (экземпляр вашего класса) нет метода lookupReferenceAgreementClassification.
Если уж так важно вызывать его именно с таблицы соглашений - переставьте переопределение метода lookupReference на метод класса и из этого метода уже и вызывайте лукапный метод, живущий на таблице.

[Pandasama]

Что касается отсутствия параметров в lookupreference

В стандартных местах, например, так:

dialogFromAccount = dialog.addFieldValue(extendedtypestr(MainAccountRecId), fromAccountRecId, "@SYS135766");
    dialogFromAccount.registerOverrideMethod(methodstr(FormReferenceControl, resolveReference), methodstr(LedgerExchAdj, mainAccountResolveReference), this);
    dialogFromAccount.registerOverrideMethod(methodstr(FormReferenceControl, lookupReference), methodstr(LedgerExchAdj, mainAccountLookupReference), this);

public Common mainAccountLookupReference(FormReferenceControl _formReferenceControl)
{
    return MainAccount::lookupReference(_formReferenceControl);
}

т.е. лукап вполне с параметром

[Pandasama]

Спасибо, помогло, тему можно закрывать.