While select.... и итерация

[vadimiron]

Такой вопрос для укрепления знаний

Например, я могу получить всех клиентов:

CustTable custTable;
;

select custTable;

Далее я хочу итерировать по полученному списку клиентов - как это сделать правильно без повторных запросов к базе данных?

Насколько я понимаю, если написать

while select custTable{}

то custTable будет опять браться из базы. Или всё же уже из самого ранее выбранного custTable??

[crazysolntse]

можно написать next custtable; - так нового запроса не будет

а "while select custtable" - Будет новый запрос к БД

[kashperuk]

А еще лучше просто сразу написать

CustTable custTable;
;
while select custTable
{

}

[vadimiron]

А в случае "next custtable" нужно делать сбрасывание курсора, если я хочу с начала итерацию начать??

Дело в том, что запрос (select custTable where....) происходит в одной функции, а вот итерация по результату запроса происходит в нескольких других - то есть мне нужно несколько раз пройтись по результату запроса без повторного обращения к базе данным

[lev]

можно конечно вот так:

CustTable custTable;
;
select custTable;

while(custTable)
{
print custTable.AccountNum;
next custTable;
}

Но в таком варианте:
1. Самое первое и главное можно забыть про NEXT и тогда уйдем в бесконечный цикл!
2. Менее читабельно.

Так что самый правильный вариант, это как советует kashperuk

[vadimiron]

lev - мне надо запрос и итерацию по результату разделить в разные функции

[Михаил Андреев]

Цитата:

Сообщение от vadimiron

Дело в том, что запрос (select custTable where....) происходит в одной функции, а вот итерация по результату запроса происходит в нескольких других - то есть мне нужно несколько раз пройтись по результату запроса без повторного обращения к базе данным

А зачем так сделали? Ещё можно воспользоваться Query, если нужно какие-то параметры запроса использовать несколько раз. Но, чтобы чётко сказать, что лучше, нужно знать задачу.

[lev]

Цитата:

Сообщение от vadimiron

lev - мне надо запрос и итерацию по результату разделить в разные функции

В таком случае действительно нужно сделать так как я написал. Но одно но я не знаю как в таком синтаксисе сбросить курсор, и возможно ли вообще такое знаю как эту проблему решить чере query:

queryRun.reset();

[glibs]

Цитата:

Сообщение от vadimiron

...
Например, я могу получить всех клиентов:

CustTable custTable;
;

select custTable;

Так вы отправите в БД запрос.

Цитата:

Сообщение от vadimiron

...
Насколько я понимаю, если написать

while select custTable{}

то custTable будет опять браться из базы. Или всё же уже из самого ранее выбранного custTable??

Аксапта работает с БД с помощью так называемого механизма курсора.

Отправляя в БД запрос вы как-бы формируете множество записей, которые вам выдаст БД. По этому списку вы можете двигаться взад-вперед. Реально в СУБД создается некий объект, дергая который вы можете получать следующую запись, и, при необходимости, обновлять или удалять ее.

Данные из БД в Аксапте вы всегда получаете по одной записи. Между клиентом и АОСом действует уже иной механизм.

Т.о. получение следующей записи не порождает новый запрос, а работает с изначальным. Почитайте про механизм курсоров в документации по MS SQL Server.

[lev]

Вот полный пример работы с query:

static void AEliz_test(Args _args)
{
    Query                   query = new Query();
    QueryRun                queryRun;
    QueryBuildDataSource    qbds;
    CustTable               custTable;
    ;

    qbds    = query.addDataSource(tableNum(CustTable));

    queryRun = new QueryRun(query);

    while(queryRun.next())
    {
        print custTable.AccountNum;
    }

    queryRun.reset();

    while(queryRun.next())
    {
        print custTable.AccountNum;
    }
}

соответственно в классе нужно объявить queryRun глобально (в ClassDeclaration) чтобы потом дёргать его отовсюду.

P.S. кстати, в случае с query не нужно думать про NEXT всё делается само автоматически, а это огромный плюс.

[glibs]

Более правильная версия полного примера.

static server void glibs(Args _args)
{
    Query                   query = new Query();
    QueryRun                queryRun;
    QueryBuildDataSource    qbds;
    CustTable               custTable;
    ;

    qbds    = query.addDataSource(tableNum(CustTable));

    queryRun = new QueryRun(query);

    while(queryRun.next())
    {
        custTable = queryRun.get(tablenum(CustTable));
        print custTable.AccountNum;
    }

    queryRun.reset();

    while(queryRun.next())
    {
        custTable = queryRun.get(tablenum(CustTable));
        print custTable.AccountNum;
    }

    pause;

}

[lev]

Цитата:

Сообщение от glibs

Более правильная версия полного примера.
...

Да действительно, забыл про инициализацию таблицы, сорри

[coolibin]

Цитата:

Сообщение от vadimiron

хочу итерировать по полученному списку клиентов - как это сделать правильно без повторных запросов к базе данных?

посмотри RecordSortedList

http://msdn.microsoft.com/en-us/library/aa862829.aspx