Ограничение выпадающего списка

[Katuxa]

Всем Добрый день!
Подскажите как реализовать следующее.
Есть две формы: Номенклатуры и Работы. Нужно чтобы в форме работ в поле Код номенклатуры отображались только те номенклатуры, которые не привязаны к работам.
Пишу след. код в методе lookup() контрола:

public void lookup()
{
   Query                   query = new Query();
   QueryBuildDataSource    qbds;
   QueryBuildRange         queryBuildRange;
   SysTableLookup  lookup = SysTableLookup::newParameters(tablenum(InventTable), this);
   InventTable     invent;
   HCSJobTable     jobTable;
   ;

   lookup.addLookupfield(fieldnum(InventTable, ItemId));
   lookup.addLookupfield(fieldnum(InventTable, ItemName));
   lookup.addLookupfield(fieldnum(InventTable, ItemGroupId));
   lookup.addLookupfield(fieldnum(InventTable, NameAlias));
   lookup.addLookupfield(fieldnum(InventTable, ItemType));
   lookup.addLookupfield(fieldnum(InventTable, DimGroupId));

   qbds = query.addDataSource(tablenum(InventTable));

   select itemId from jobTable
    where jobTable.itemId != ''; //или следующий запрос
   //select itemId from invent notexists join itemId from jobTable;

   findOrCreateRange_W(qbds, fieldnum(InventTable, ItemType), enum2str(ItemType::BOM));
   queryBuildRange = qbds.addRange(fieldnum(InventTable, ItemId));
   queryBuildRange.value(???????);
 
   lookup.parmQuery(query);
   lookup.performFormLookup();

   //super();
}

Не знаю как указать значение queryBuildRange.

[S.Kuskov]

QueryBuildDataSource    qbdsHCSJobTable;
...
//   queryBuildRange = qbds.addRange(fieldnum(InventTable, ItemId));
//   queryBuildRange.value(???????);
qbdsHCSJobTable = qbds.addDataSource(tableNum(HCSJobTable));
qbdsHCSJobTable.joinMode(joinMode::NoExistsJoin);

[Katuxa]

Цитата:

Сообщение от S.Kuskov

QueryBuildDataSource    qbdsHCSJobTable;
...
//   queryBuildRange = qbds.addRange(fieldnum(InventTable, ItemId));
//   queryBuildRange.value(???????);
qbdsHCSJobTable = qbds.addDataSource(tableNum(HCSJobTable));
qbdsHCSJobTable.joinMode(joinMode::NoExistsJoin);

Написала так, но все-равно не работает. Выпадает пустой список, хотя список номенклатур большой и они почти все не привязаны.

[S.Kuskov]

Цитата:

Сообщение от Katuxa

Написала так, но все-равно не работает. Выпадает пустой список, хотя список номенклатур большой и они почти все не привязаны.

Проверьте есть ли связь между таблицами InventTable и HCSJobTable.

[Katuxa]

Связь указана в Relations в таблице HCSJobTable.

[S.Kuskov]

Нужно ещё одну строку добавить в код. Вот так:

qbdsHCSJobTable = qbds.addDataSource(tableNum(HCSJobTable));
qbdsHCSJobTable.joinMode(joinMode::NoExistsJoin);
qbdsHCSJobTable.relation(true); // !!!

[Katuxa]

Цитата:

Сообщение от S.Kuskov

Нужно ещё одну строку добавить в код. Вот так:

qbdsHCSJobTable = qbds.addDataSource(tableNum(HCSJobTable));
qbdsHCSJobTable.joinMode(joinMode::NoExistsJoin);
qbdsHCSJobTable.relation(true); // !!!

Получилось . Спасибо вам огромное!!!