Как в отладчике посмотреть значение parm-метода?

[dit31]

(AX 2012 R2)
Подскажите, пожалуйста, как в отладчике посмотреть значение parm-метода?
parm-методы по сути являются оберткой для переменных класса.
Как в отладчике можно посмотреть их текущие значения.
Конкретно интересует element.args()

[gl00mie]

element.args() - это не parm-метод, это свойство объекта ядра (формы), а то, что лежит в Args, - это свойства другого объекта ядра, который является значением свойства формы. Отладчик в общем случае не умеет показывать значения свойств объектов ядра, таких как форма. Но в Args заглянуть отчасти может - если вытащить ссылку на них в переменную в calssDeclaration формы либо какого-то метода на ней. При этом отображаемое "содержимое" Args - это то, что сам класс показывает в ответ на вызов toString(). Из объектов ядра сколь-нибудь подробно отладчик умеет показывать разве что свойства FormControl'ов.

[dit31]

А значения обычных самописных parm-методов отладчик может показывать? Для этого метод должен начинаться на "parm"?

[gl00mie]

Нет, для отладчика X++ что parm-метод, что любой другой - это именно метод. Отладчик штатно умеет вызывать только метод toString() объектов. Чтобы посмотреть "значение" parm-метода, надо знать, что именно тот возвращает, и если это - какая-то переменная класса, то в отладчике развернуть соотв. объект в окне Locals и найти в нем эту переменную. Если отладчик находится в коде объекта, "значение" parm-метода которого надо посмотреть, то разворачивать надо this.

[ice]

можно "провалится" в метод сделав шаг и там посмотреть, что возвращается

[gl00mie]

Это есть parm-метод вызывается непосредственно в отлаживаемом коде

[Stitch_MS]

Еще можно добавить в АОТ небольшой класс и использовать его при отладке:

 class ParmMethodViewer
{
    Object object;
     Map parmMethodName2Value;
}
 
 void initMap()
{
    DictClass    dictClass;
    int          methodIdx;
    str          methodName;
    Object       parmObject;
    Common       parmCommon;
    anytype      parmPrimitive;
    Types        type;
    ;
 
     parmMethodName2Value = new Map(Types::String, Types::String);
 
     dictClass = new DictClass(classidget(object));
     for(methodIdx = 1; methodIdx <= dictClass.objectMethodCnt(); methodIdx++)
    {
        methodName = dictClass.objectMethod(methodIdx);
         if (!strStartsWith(methodName, 'parm'))
        {
            continue;
        }
 
         type = typeOf(dictClass.callObject(methodName, object));
 
        switch (type)
        {
            case Types::Class:
                parmObject = dictClass.callObject(methodName, object);
                parmMethodName2Value.insert(
                    methodName,
                    classId2Name(classidget(parmObject)));
                break;
 
             case Types::Record:
                parmCommon = dictClass.callObject(methodName, object);
                parmMethodName2Value.insert(
                    methodName,
                        strFmt('Table %1, RecId %2',
                            tableid2name(parmCommon.TableId),
                            parmCommon.RecId));
                break;
 
             case Types::String,
                 Types::Date,
                 Types::Guid,
                 Types::Int64,
                 Types::Integer,
                 Types::Real,
                 Types::Time,
                 Types::UtcDateTime:
                parmPrimitive = dictClass.callObject(methodName, object);
                parmMethodName2Value.insert(
                    methodName,
                    strFmt('%1', parmPrimitive));
                break;
        }
    }
}
 
 void new(Object _object)
{
    ;
     object = _object;
 
     this.initMap();
}

Примеры использования:

 public static void main(Args _args)
{
    Args             args;
    InventTable      inventTable;
     ParmMethodViewer parmMethodViewer;
    ;
 
     args = new Args();
    args.parm('qwerty');
    args.parmEnumType(enumnum(NoYes));
    args.parmObject(new SalesFormLetter_Invoice());
 
     parmMethodViewer = new ParmMethodViewer(args);
     breakpoint;
 
     select firstonly inventTable;
     parmMethodViewer = new ParmMethodViewer(AxInventTable::newInventTable(inventTable));
     breakpoint;
}

На первой точке остановки переменная parmMethodName2Value будет иметь значение ["parm"->"qwerty","parmEnumType"->"61469","parmObject"->"SalesFormLetter_Invoice"]

На второй:

["parmAltConfigId"->"","parmAltInventColorId"->"","parmAltInventSizeId"->"","parmAltItemId"->"","parmAssetGroupId_RU"->"","parmAssetId_RU"->"","parmBatchNumGroupId"->"","parmBOMCalcGroupId"->"","parmBOMLevel"->"0","parmBOMUnitId"->"pcs", ...

Но тут нужно быть уверенным, что все parm-методы объекта написаны по бест-практисам и ничего другого не делают.

[Logger]

Как лучше отлаживать код с временными таблицами, recordset'ами, set'ами, map'ами и прочими сложными структурами?
Отладка сложных объектов. Как лучше?