QueryBuildDataSource - получить поля группировок

[Link]

Вот хороший пример из \Data Dictionary\Tables\InventDim\Methods\queryGetSortAndGroupByFields

/// <summary>
///    Gets the list of fields being sorted and grouped by in the specified query.
/// </summary>
/// <param name="_query">
///    The query to examine.
/// </param>
/// <param name="_includeGroupByFields">
///    true if <c>GroupByFields</c> at the query level should be examined too.
/// </param>
/// <returns>
///    A list of field IDs.
/// </returns>
client server static private List queryGetSortAndGroupByFields(
    Query                   _query,
    boolean                 _includeGroupByFields
)
{
    QueryBuildDataSource    qbsDim = _query.dataSourceTable(tableNum(InventDim));
    Counter                 h;
    FieldId                 inventDimFieldId;
    QueryGroupByField       groupByField;
    List                    fieldList = new List(Types::Integer);

    for (h = 1; h <= qbsDim.sortFieldCount(); h++)
    {
        inventDimFieldId = qbsDim.sortField(h);
        fieldList.addEnd(inventDimFieldId);
    }

    if (_includeGroupByFields)
    {
        for (h = 1; h <= _query.groupByFieldCount(); h++)
        {
            groupByField = _query.groupByField(h);
            if (groupByField.tableSelector() == tableNum(InventDim))
            {
                inventDimFieldId = groupByField.fieldID();
                fieldList.addEnd(inventDimFieldId);
            }
        }
    }
    return fieldList;
}