ReqPO и ReqTrans - планирование - DAX: Программирование

Rimantas · 17.01.2007, 15:08

Здраствуйте ,

Мои шефы хотят чтобы в "Спланированных заказах" были видные данные для какого заказа пордажи есть запланирована строка . В первые я сделал как отображение через метод и он действует ( не на все строки ) . Но , как вы знаете , на такую информацию неработает поиск и филтрирование . Я буду добавлят два поля в ReqPO табличку - SalesId и CustName и заполню ети поля нужной информации . Вопрос в том , что я пока непонимаю как добиться до SalesId по настоящему . Вот мой метод отображения - и он не действует на все 100 % .. :-(( :

Код:

  Display InventTransRefId refId( Int nRez = 1 )
  {
    InventTransRefId cRet;
    ReqTrans         reqTrans, reqTrans2;
    ReqTransCov      reqCov;
    Salestable       salTbl;
    CustTable        cstTbl;
    ReqPO            reqPo;
    ;
    reqTrans  = this.reqTrans();
    reqCov    = reqTrans.selectCov(false);
    reqtrans2 = reqtrans.reqTransSettled(reqCov,false);
    if ( reqTrans2 )
    {
       cRet = reqTrans2.RefId;
       salTbl = salestable::find(cRet);
       if ( salTbl )
       {
          if ( nRez == 1 )
          {
             cstTbl = CustTable::find(salTbl.CustAccount);
             cRet = cRet + " " + cstTbl.Name;
          }
       }
       else
       {
          cRet = "";
          reqPo = ReqPo::find(reqTrans2.ReqPlanId,reqTrans2.RefId,false);
          if ( reqPo )
          {
             reqTrans  = reqPo.reqTrans();
             reqCov    = reqTrans.selectCov(false);
             reqtrans2 = reqtrans.reqTransSettled(reqCov,false);
             if ( reqTrans2 )
             {
                cRet = reqTrans2.RefId;
                salTbl = salestable::find(cRet);
                if ( salTbl )
                {
                   if ( nRez == 1 )
                   {
                      cstTbl = CustTable::find(salTbl.CustAccount);
                      cRet = cRet + " " + cstTbl.Name;
                   }
                }
             }
             else
             cRet = "";
          }
       }
    }
    return cRet;
  }

Буду благодарен если поясните , как можно добиться до продажного заказа для каждой строки из спланированных заказов . А то голова крутиться уже ...

С уважением , Римантас

EVGL · 17.01.2007, 16:02

Пожалуйста: приведенный ниже код копирует поле из SalesLine в ReqPO. Практически ваш случай.

X++:

// EVGGL, PT0616 -->
protected void TCHUpdatePlannedOrderSalesPoolId(ReqSetupDim _setupDim)
{
    ReqTrans            reqTrans;
    ReqTransCov         reqTransCov;
    ReqTrans            reqTransSettled;
    SalesPoolId         salesPoolId, oldSalesPoolId;
    ReqPO               reqPO;

    Map                 mapPlannedOrder;
    MapIterator         mi_PlannedOrder;
    Map                 mapReqTransReceipts;

    ReqTransCache       reqTransCache   = reqPlanData.reqTransCache();

    mapPlannedOrder = reqTransCache.mapPlannedOrder();
    mapReqTransReceipts = reqTransCache.findReceipts(_setupDim);
    if (! mapPlannedOrder || ! mapReqTransReceipts)
        return;
    mi_PlannedOrder = new mapIterator(mapPlannedOrder);

    mi_PlannedOrder.begin();
    while (mi_PlannedOrder.more())
    {
        // ignore planned order coming from another cycle
        if (! mapReqTransReceipts.exists(mi_PlannedOrder.key()))
        {
            mi_PlannedOrder.next();
            continue;
        }

        reqTrans = mapPlannedOrder.lookup(mi_PlannedOrder.key());
        salesPoolId     = "";
        oldSalesPoolId  = "";

        if (reqTrans.CovQty && ! reqTrans.IsDerivedDirectly && ! reqTrans.IsForecastPurch &&
            (reqTrans.RefType == ReqRefType::ItemPlannedOrder || reqTrans.RefType == ReqRefType::BOMPlannedOrder))
        {
            reqTransCov     = reqTrans.selectCovJoinTrans(true);
            reqTransSettled = reqTransCov.joinChild();
            while (reqTransCov)
            {
                if (reqTransCov.Qty == 0)
                    continue;

                if (! reqTransSettled.InventTransId || ! reqTransSettled.RefId || reqTransSettled.RefType != ReqRefType::Sales)
                {
                    // There cannot be any common relation
                    salesPoolId = "";
                    break;
                }

                salesPoolId = SalesLine::findInventTransId(reqTransSettled.InventTransId).TCHSalesPoolId;
                if (! salesPoolId)
                    break;
                if (oldSalesPoolId && salesPoolId != oldSalesPoolId)
                {
                    salesPoolId = "";
                    break;
                }
                oldSalesPoolId = salesPoolId;

                next reqTransCov;
            }
            if (salesPoolId)
            {
                reqPO = reqTrans.reqPo(true);
                reqPO.TCHSalesPoolId = salesPoolId;
                reqPO.doUpdate();
            }
        }

        mi_PlannedOrder.next();
    }
}

Этот новый метод вызывается из ReqCalc.covCalc:

X++:

...
                                    }
                                    // EVGGL, PT0616 -->
                                    this.TCHUpdatePlannedOrderSalesPoolId(setupDim);
                                    // EVGGL, PT0616 <--
                                }

                                ttscommit;
                            }
                            catch (Exception::Deadlock)
...

Разумеется, все это работает только в модели планирования "1:1". В противном случае вы получаете одну закупку, которая "закрывает" несколько заказов на продажу.

kashperuk · 17.01.2007, 16:04

оффтоп:
а почему EVGGL ?!?

EVGL · 17.01.2007, 16:06

Цитата:

Сообщение от kashperuk

оффтоп:
а почему EVGGL ?!?

В той компании, в которой я сейчас работаю, в ходу 5-символьные логины.

Rimantas · 17.01.2007, 16:17

Цитата:

Сообщение от EVGL

Пожалуйста: приведенный ниже код копирует поле из SalesLine в ReqPO. Практически ваш случай.
...
Разумеется, все это работает только в модели планирования "1:1". В противном случае вы получаете одну закупку, которая "закрывает" несколько заказов на продажу.

БОЛЬШОЕ СПАСИБО !!!

. Только хочу переспросить - где поместить етот метод TCHUpdatePlannedOrderSalesPoolId , в какoй класс ?

Ещё раз СПАСИБО ! Римантас

EVGL · 17.01.2007, 16:19

ReqCalc, очевидно.

Andrew K. · 17.01.2007, 18:03

Евгений, правильно ли я понимаю что Ваш код обрабатывает только непосредственно связанные ReqTrans, т.е. через уровни Sales - Prod - ProdBOM - Purch или Sales - Transfer - Purch функция не работает?

EVGL · 17.01.2007, 20:49

Цитата:

Сообщение от Andrew K.

Евгений, правильно ли я понимаю что Ваш код обрабатывает только непосредственно связанные ReqTrans, т.е. через уровни Sales - Prod - ProdBOM - Purch или Sales - Transfer - Purch функция не работает?

Верно.

Rimantas · 18.01.2007, 09:32

Цитата:

Сообщение от EVGL

ReqCalc, очевидно.

Замечательно ... Вечером пропускали планирование - всё работает !

EVGL , простите , но ещё хочу попросить совета . В некоторых случаях планирование делает в ручную - из заказов продажи делает Explosion ( форма ReqTransExplosion ) . Здесь ваш метод действует на главную строку заказа ( продукт ) , но незаполняет для строк составляюших продукта . Может быть и для етого у вас есть решение ?

...

С благодарносьтю , Римантас

Vals · 18.01.2007, 10:28

Цитата:

чтобы в "Спланированных заказах" были видные данные для какого заказа пордажи есть запланирована строка

А в нижней части "Использование" не то что нужно отображает?

EVGL · 18.01.2007, 10:32

Цитата:

Сообщение от Rimantas

Здесь ваш метод действует на главную строку заказа ( продукт ) , но незаполняет для строк составляюших продукта . Может быть и для етого у вас есть решение ?

К сожалению, готового решения нет. Это как раз то, о чем написал Andrew K.

Rimantas · 18.01.2007, 10:32

Цитата:

Сообщение от Rimantas

Может быть и для етого у вас есть решение ?

...

X++:

[B]            if ( !salesid && reqTransSettled )
            {
               reqPO = reqTransSettled.reqPo(false);
               if ( reqPO.SalesId )
                  salesId = reqPO.SalesId;
            }[/B]            if ( salesId )
            {
               reqPO = reqTrans.reqPo(true);
               if ( salesid != reqPO.SalesId )
               {
                  reqPO.SalesId   = salesId;
                  reqPO.SalesName = Salestable::find(salesId,false).SalesName;
                  reqPO.doUpdate();
               }
            }

Решено ...

Добавил ети строки , так что если не нашли , то шаг назад с reqTransSettled . Действует хорошо ...

Спасибо ! Римантас

Rimantas · 18.01.2007, 10:37

Цитата:

Сообщение от Vals

А в нижней части "Использование" не то что нужно отображает?

В нижней части показывает только один раз продажный заказ - на конечный продукт . А на всех остальных - последовательность запланированных заказов . И проблема здесь в том , как филтрировать и найти кучу информации для конкретного заказа продажи . Так что для етого в ReqPO полей маловато ...

Решение EVGL - очень хорошее .

С уважением , Римантас

Похожие темы
Тема	Автор	Раздел	Ответов	Посл. сообщение
Как правильно создать в коде X++ новый planned order (ReqPO, ReqTrans)	rkorchagin	DAX: Программирование	5	02.06.2016 18:00
Планирование номенклатуры с типом Основное средство	AlexeyBP	DAX: Функционал	19	29.01.2009 07:42
Отличия в строках ReqPO, почему одна строка появляется в форме а другая нет (Master Planning, Planned Orders)	rkorchagin	DAX: Программирование	8	21.02.2007 16:27
Планирование производственных операций	Vikp	DAX: Функционал	4	10.01.2006 15:43
Заказ -> Сводное планирование -> Изменение даты заказа	ARRTEMka	DAX: Функционал	8	14.02.2005 14:46

Опции темы	Поиск в этой теме
Версия для печати Отправить по электронной почте	Поиск в этой теме: Расширенный поиск
Опции просмотра
Линейный вид Комбинированный вид Древовидный вид