lookup для ItemId iz InventTable + InventDim + InventSum

[stalker25]

Здравствуйте, есть одна проблема может кто знает
для ItemId сделать lookup с выборкой по AvailPhysical из InventSum,
я в коде в коментарии оставил вопрос на последнем этапе

queryBuildDataSource = query.addDataSource(tablenum(InventTable));

   
    queryBuildRange = queryBuildDataSource.addRange(fieldnum(InventTable, ItemId));
    queryBuildRange.value(Criteria1);

    //addn new data source
    queryBuildDataSource1 = queryBuildDataSource.addDataSource(tablenum(InventItemLocation));
    queryBuildDataSource1.addLink(fieldnum(InventTable, ItemId),fieldnum(InventItemLocation,ItemId));
    queryBuildDataSource1.joinMode(JoinMode::InnerJoin);
    queryBuildDataSource1.addRange(fieldnum(InventItemLocation, wMSPickingLocation)).value(criteria2);

    queryBuildDataSource2 = queryBuildDataSource1.addDataSource(tablenum(InventDim));
    queryBuildDataSource2.addLink(fieldnum(InventItemLocation,InventDimId),fieldnum(InventDim,InventDimId));
    queryBuildDataSource2.joinMode(JoinMode::InnerJoin);
    queryBuildDataSource2.addRange(fieldnum(InventDim, InventLocationId)).value(criteria3);

//вот тут join получается  тока для InventDim либо InventTable, а мне нужно что б брал //значение с 2 таблиц сразу InventDim.InventDimId i  InventTable.ItemId
   
 queryBuildDataSource3 = queryBuildDataSource.addDataSource(tablenum(InventSum));
    queryBuildDataSource3.addlink(fieldnum(InventTable, ItemId),fieldnum(InventSum,ItemId));
queryBuildDataSource3.addlink(fieldnum(InventDim, InventDimId),fieldnum(InventSum,InventDimId));
    queryBuildDataSource3.joinMode(JoinMode::InnerJoin);
    
    queryBuildDataSource3.addRange(fieldnum(InventSum, AvailPhysical)).value(strfmt("%1",">0"));

[Wamr]

например, перестроить отчет так:
InventTable
+ItemId
InventItemLocation
+ItemId +InventDimId
InventSum
+InventDimId
InventDim

[stalker25]

Вы верно заметили, но проблема, что в таком виде lookup работает в разы дольше! может всё таки есть спопсоб перетащить itemid в addlink в InventSum, см код выше?

[gl00mie]

Цитата:

Сообщение от stalker25

может всё таки есть спопсоб перетащить itemid в addlink в InventSum, см код выше?

Можно попробовать использовать расширенный range:

Range   range;
;
// ...
range = strfmt( @"((%1.%2==%3.%4))", queryBuildDataSource2.name(), fieldstr(InventDim, InventDimId),
                                     queryBuildDataSource3.name(), fieldstr(InventSum, InventDimId)
              );
queryBuildDataSource3.addRange(fieldnum(InventSum, InventDimId)).value( range );

[lev]

можно добавить FetchMode, мне помогало при линках... например:

queryBuildDataSource3.FetchMode(QueryFetchMode::One2One);

только точно не помню хватит добавления этого параметра только в одном линке или нужно будет добавить во всех (я обычно добавляю во всех )

[lev]

проверил у себя, вот получился рабочий вариант построения запроса, подцепились все датасорсы

queryBuildDataSource = query.addDataSource(tablenum(InventTable));


    queryBuildRange = queryBuildDataSource.addRange(fieldnum(InventTable, ItemId));
    queryBuildRange.value(Criteria1);

    //addn new data source
    queryBuildDataSource1 = queryBuildDataSource.addDataSource(tablenum(InventItemLocation));
    queryBuildDataSource1.addLink(fieldnum(InventTable, ItemId),fieldnum(InventItemLocation,ItemId));
    queryBuildDataSource1.joinMode(JoinMode::InnerJoin);
    queryBuildDataSource1.addRange(fieldnum(InventItemLocation, wMSPickingLocation)).value(criteria2);
    queryBuildDataSource1.fetchMode(QueryFetchMode::One2One);

    queryBuildDataSource2 = queryBuildDataSource1.addDataSource(tablenum(InventDim));
    queryBuildDataSource2.addLink(fieldnum(InventItemLocation,InventDimId),fieldnum(InventDim,InventDimId));
    queryBuildDataSource2.joinMode(JoinMode::InnerJoin);
    queryBuildDataSource2.addRange(fieldnum(InventDim, InventLocationId)).value(criteria3);
    queryBuildDataSource2.fetchMode(QueryFetchMode::One2One);
//вот тут join получается  тока для InventDim либо InventTable, а мне нужно что б брал //значение с 2 таблиц сразу InventDim.InventDimId i  InventTable.ItemId

    queryBuildDataSource3 = queryBuildDataSource.addDataSource(tablenum(InventSum));
    queryBuildDataSource3.addlink(fieldnum(InventTable, ItemId),fieldnum(InventSum,ItemId));
    queryBuildDataSource3.addlink(fieldnum(InventDim, InventDimId),fieldnum(InventSum,InventDimId));
    queryBuildDataSource3.joinMode(JoinMode::InnerJoin);

    queryBuildDataSource3.addRange(fieldnum(InventSum, AvailPhysical)).value(strfmt("%1",">0"));
    queryBuildDataSource3.fetchMode(QueryFetchMode::One2One);

[stalker25]

спасибо, проверил работают оба способа.