Копирование Range по имени (2.5)

[Wamr]

Понадобилось мне скопировать набор range из одной таблицы в другую по одноименным полям.
Код, который воспроизводит данный процесс на тестовой формочке:

PHP код:

    Query                   q, qn = new Query();
    QueryBuildDataSource    qbDS, qbDSn;
    DictTable               dictTableSour, dictTableDest;
    FieldId                 fieldId_Dest, fieldId_Sour;

    str 100     qv;
    int         i;
    ;

    super();

    if(InventTable_ds.queryRun())
        q = InventTable_ds.queryRun().query();
    else
        q = InventTable_ds.query();

    qbDS  = q.dataSourceNo(1);
    qbDSn = qn.addDataSource(qbDS.table());

    dictTableSour = new DictTable(qbDS.table());
    dictTableDest = new DictTable(qbDSn.table());

    for(i = 1; i <= qbDs.rangeCount(); i++)
    {
        fieldId_Sour = qbDS.range(i).field();
        fieldId_Dest = dictTableDest.fieldName2Id(dictTableSour.fieldName(fieldId_Sour));
//        fieldId_Dest = fieldId_Sour;

        qv = qbDS.range(i).value();
        if(fieldId_Sour && fieldId_Dest)
            qbDSn.addRange(fieldId_Dest).value(qv);
    }

    info(qbDS.toString());
    info(qbDSn.toString()); 


И все работало, пока не попался "хитрый" запрос с несколькими range по одному полю. В результирующем запросе получился OR между этими ограничениями вместо AND из исходного.

Создал тестовый пример - форма с одним DS (InventTable) в init устанавливается фильтр на поле ItemId. При установке пользовательского фильтра на этоже поле и копировании ограничений получаем:
[FIG1]

Кто-то может объяснить такой феномен?

[Dron AKA andy]

Ну так все правильно, при добавлении ranges по одному полю они объединяются по ИЛИ (было бы странно, если бы поле имело одновременно 2 значения , а более общие условия можно исключить как избыточные), а по разным полям - по И. Интересно, как ты получил такой исходный запрос с И?

[Dron AKA andy]

Wamr, извини, только сейчас заметил, что прикреплен пример формы. Теперь увидел, как получается такой запрос...

Но addRange(), тем не менее, работает только так.

[Dron AKA andy]

Кстати, разные результаты в 2.5 и 3.0!

В 2.5 работает как описано у тебя, а в 3.0 вообще при наложении фильтра остается только 1 range, последний:

SELECT * FROM InventTable WHERE ((ItemId = 10817))

[Wamr]

Цитата:

Изначально опубликовано Dron AKA andy
Но addRange(), тем не менее, работает только так.

Тогда покажу тебе фокус

PHP код:

...
    int         i, shift;
    ;
...

    for(i = 1; i <= qbDs.rangeCount(); i++)
    {
        fieldId_Sour = qbDS.range(i).field();
        shift = fieldId_Sour & 0xFFFF0000;
        fieldId_Dest = dictTableDest.fieldName2Id(dictTableSour.fieldName(fieldId_Sour)) | shift;
... 


Но почему это так я не догоняю.

[Wamr]

Цитата:

Изначально опубликовано Dron AKA andy
Кстати, разные результаты в 2.5 и 3.0!

В 2.5 работает как описано у тебя, а в 3.0 вообще при наложении фильтра остается только 1 range, последний:

SELECT * FROM InventTable WHERE ((ItemId = 10817))

Это я тоже заметил. Очень неприятная фича.
Например, я из кода установил range со статусом LOCK, потом пользователь установил свой фильтр по томуже полю. В результате юзер не сможет поправить фильтр из стандартной формы фильтрации, так как статус у него сохранился (LOCK).
Или еще. Опять же из кода поставили фильтр, потом пользователь установил свой, теперь у меня нет возможности грохнуть свой и сохранить юзерский.

[Dron AKA andy]

Цитата:

shift = fieldId_Sour & 0xFFFF0000;

а откуда это взято, не интуитивно же выведено ?

Добавление:
А, понял, все же по info() видно

[Wamr]

Методом проб и ошибок.
Раньше часто замечал, что некоторые методы возвращают вместо fieldId значение 0x10000 + fieldId, но закономерности не видел.
В данном случаи range добавленый программно возвращает fieldId, а вот добавленный юзер fieldId "с хвостиком".
И что самое прикольно addRange понимает оба варианта, но воспринимает их как разные поля (т.е. объединяет по AND).

[Wamr]

В Global есть метод

PHP код:

/*
    Returns the fieldId part of an extended FieldId
    (an extended FieldId is a fieldId including the array index)
*/
static fieldId fieldExt2Id(fieldId fieldExtId)
{
    return (fieldExtId & 0xFFFF);
} 


Что-то он мне напоминает

[Wamr]

PHP код:

static void Job_2(Args _args)
{
    Query           q;
    QueryRun        qr;

    QueryBuildDataSource    qbDS;
    ;

    q = new Query();

    qbDS = q.addDataSource(tableNum(InventTable));
    qbDS.orderMode(OrderMode::GROUPBY);
    qbDS.addSelectionField(fieldNum(InventTable, RecId), SelectionField::COUNT);

    qbDS.addRange(fieldNum(InventTable, ItemId)).value("A..");
    qbDS.addRange(fieldNum(InventTable, ItemId)).value("..D");

    info(qbDS.toString());

    qr = new QueryRun(q);
    while(qr.next())
        info(int2str(qr.getNo(1).RecID));

    qbDS.clearRanges();
    qbDS.addRange(fieldNum(InventTable, ItemId)).value("A..");
    qbDS.addRange(fieldId2Ext(fieldNum(InventTable, ItemId), 1)).value("..D");

    info(qbDS.toString());

    qr = new QueryRun(q);
    while(qr.next())
        info(int2str(qr.getNo(1).RecID));
} 


Причем попытка написать fieldId2Ext(fieldNum(InventTable, ItemId), 2) приводит к ошибке.
Т.е. любое простое поле имеет дублирующий fieldId, как будто поле является первым и единственным элементом массива.