conPeek() и common.dataareaID

[Logger]

Коллеги, кто-нибудь знает способ, как можно извлечь буфер из контейнера и сохранить оригинальное значение dataareaID.

Суть проблемы в том, что при извленчении буфера из контейнера, ядро заново констрактит экземпляр common, соответственно в common.datareaID кладется текущая компания, а исходное значение этого поля теряется. Таким образом если мы имеем контейнер содержащий буфер, то непонятно как определить его компанию. Есть какой нибудь нормальный способ ?

[glibs]

static void glibs(Args _args)
{
CustTable custTable;
List list;
ListEnumerator listEnumerator;
;

list = new List(Types::Record);
select firstonly custTable;
list.addEnd(custTable);

changecompany ("DAT")
{
listEnumerator = list.getEnumerator();
while (listEnumerator.moveNext())
{
custTable.data(listEnumerator.current());
info (strfmt("%1", custTable.dataAreaId));
}
}

}

[Logger]

Спасибо. Пример хороший.

Но вопрос был про контейнеры.
Для них все плохо.

Немного переделал джоб для иллюстрации. (Запускать надо не в компании dat)

static void glibs(Args _args)
{
container   con;
CustTable custTable;
CustTable custTable2;
CustTable custTable3;
CustTable custTableCon;
CustTable custTableCon2;
CustTable custTableCon3;

List list;
ListEnumerator listEnumerator;
;

    list = new List(Types::Record);
    select firstonly custTable;
    list.addEnd(custTable);
    con = [custTable];

    changecompany ("DAT")
    {
        listEnumerator = list.getEnumerator();
        while (listEnumerator.moveNext())
        {
            custTable.data(listEnumerator.current());
            custTable2.data(listEnumerator.current());
            custTable3 = listEnumerator.current();
            info (strfmt("%1", custTable.dataAreaId));
            info (strfmt("2 : %1", custTable2.dataAreaId));
            info (strfmt("3 : %1", custTable3.dataAreaId));

            [custTableCon] = con;
            custTableCon2 = conPeek(con,1);
            //custTableCon3 = listEnumerator.current();
            info (strfmt("Con %1", custTableCon.dataAreaId));
            info (strfmt("Con2 : %1", custTableCon2.dataAreaId));
            //info (strfmt("Con3 : %1", custTableCon3.dataAreaId));

        }
    }

}

[glibs]

Вставляйте в контейнер List с единственной записью.

А если серьезно, то почему для вас так принципиален контейнер?

[glibs]

Джоб у меня такоо плана был .

Цитата:

Сообщение от glibs

...Вставляйте в контейнер List с единственной записью...

Наверное, я имел в виду list.pack(). В смысле, тоже контейнер.

Кстати, в List можно вставить объект, в контейнер нет. Если я не ошибаюсь. А вообще мне казалось, что буфер в контейнер не вставляется. Так что спасибо, вспомнил теорию.

[Logger]

Цитата:

Сообщение от glibs

Вставляйте в контейнер List с единственной записью.

А если серьезно, то почему для вас так принципиален контейнер?

Для меня - нисколько не принципиален.

Заметил что многие разработчики любят использовать контейнеры и класть туда все скопом. У нас из-за описанного бага в некоторых местах ошибки лезли.

[glibs]

Цитата:

Сообщение от Logger

...многие разработчики любят использовать контейнеры...

IMHO им просто лень изучать как следует и потом использовать API Аксапты.

Не бросайте в меня камнями, пож. Я знаю, что вас тут много.

[Андре]

Вообще, создание классов-контейнеров (Map, List, Set) с типом Record у меня находится в списке приемов, благодаря которым можно получить проблему на ровном месте.

Уже несколько раз натыкался на случаи, когда память, выделенная на AOS под хранение Record не возвращается операционной системе даже после переиниициализации класса контейнера. Как правило, данная проблема ловится на самописных отчетах, обрабатывающих большой объем данных.

Может быть в пятерке исправили - не проверял. Кроме того, подозреваю, что существует некая критическая длинна записи, после которой начинает проявляться данная проблема, но я не экспериментировал, а просто перепаковал все необходимые поля в контейнер от греха подальше.

[DSPIC]

Есть 2 отличные функции у класса Global:
container buf2Con(Common common)
static void con2Buf(container c, Common common)
И ещё полезные: con2List, con2Str, buf2Buf, bufCmp

static void dspic(Args _args)
{
    CustTable custTable;
    container conCustTable;
    ;

    select firstonly custTable;
    
    conCustTable = buf2con(custTable);

    changecompany ("DAT")
    {
        con2buf(conCustTable, custTable);
 
        info (strfmt("%1", custTable.dataAreaId));
    }
}

[SRF]

Цитата:

Сообщение от Logger

... Есть какой нибудь нормальный способ ?

Наиболее логичным способом помещения record в контейнер, как мне кажется является вариант, предложенный DSPIC, использование функций
container buf2Con(Common common) и static void con2Buf(container c, Common common), по всей видимости они для этого и предназначены

Цитата:

Сообщение от DSPIC

Есть 2 отличные функции у класса Global:
container buf2Con(Common common)
static void con2Buf(container c, Common common)
...

static void dspic(Args _args)
{
    CustTable custTable;
    container conCustTable;
    ;
 
    select firstonly custTable;
 
    conCustTable = buf2con(custTable);
 
    changecompany ("DAT")
    {
        con2buf(conCustTable, custTable);
 
        info (strfmt("%1", custTable.dataAreaId));
    }
}

Однако стоить помнить, что функция Global \ container buf2Con(Common common) в версиях AX 3.0(возможно только в некоторых, проверял на AX 3.0 SP 2, AX 3.0 SP 3 CU 1) не работает(выпадает эксепшен), если у табличных переменных есть поля-массивы(т.е. выше описанный job работать не будет )

Также в случае использования одной табличной переменной и функции xRecord.company(...) можно получить реальную компанию(однако, если в changeCompany("dat") вместо CustTable, использовать CustTable2, то в обоих случаях будет выведено "dat")

static void srf_test(Args _args)
{
    CustTable   custTable;
    Container   conCustTable;
    ;
 
    select firstOnly custTable;
 
    conCustTable = [custTable];
 
    changecompany("dat")
    {
        custTable.clear();
        custTable.data(conpeek(conCustTable, 1));
 
        info(custTable.dataAreaId);
        info(custTable.company());
    }
}

[DSPIC]

Цитата:

Однако стоить помнить, что функция Global \ container buf2Con(Common common) в версиях AX 3.0(возможно только в некоторых, проверял на AX 3.0 SP 2, AX 3.0 SP 3 CU 1) не работает(выпадает эксепшен), если у табличных переменных есть поля-массивы(т.е. выше описанный job работать не будет )

Справедливое замечание. Лечится-то просто - добавить дополнительный пробег по полям-массивам в ф-циях buf2Con\vice versa. Но помнить, конечно, следует.

Я вот только не совсем понял, зачем вообще трогать dataAreaId? Насколько это корректно?
Читать - да, менять - не знаю. По-моему, это бубен какой-то...

[plumbum]

По моему с записями лучше уже использовать RecordSortedList / RecordInsertList - они же для этого и созданы (journalTransList)

Чтоб пихать контейнер в List можно использовать ContainerClass, для уверенности, а вообще в 4.0 и выше уже можно пихать контейнер в список

[Logger]

В 2009-й исправлено.
Теперь сохраняется исходный dataareaID.