Как сделать чтобы aspnetForm.submit не вызывал переход на новую форму

[Murlin]

Доброго времени суток!
помогите пж-ста.

Создал web форму в группе создан UserDefined элемент, перекрыт метод layout

    boolean         ret;
    str             temp;
    DictEnum        dictEnum;
    int             i;
    str     controlName;
    void createLink()
    {
        boolean         b;
        ;
        temp = temp + strfmt('<select size=1 id="%1" name="%1" onchange="fldsubmit_%1()">\n',controlName);
        dictEnum = new DictEnum(enumNum(WorkFlowAllMy));
        b = false;
        for (i=0;i<=dictEnum.values();i++)
        {
            if (dictEnum.index2Label(i))
            {
                if (workFlowAllMy == dictEnum.index2Value(i))
                {
                      temp = temp + strfmt("<option selected value=%1>%2</option>\n",dictEnum.index2Value(i),dictEnum.index2Label(i));

                }
                else
                     temp = temp + strfmt("<option value=%1>%2</option>\n",dictEnum.index2Value(i),dictEnum.index2Label(i));
            }
        }
        temp = temp + strfmt("<option value=%1>%2</option>\n",10,s12);
        temp = temp + strfmt("</select>\n");
    }
    ;
    ret = super();
    controlName = webSession().createControlName(element,this);
    temp = '<SCRIPT language="javascript" type="text/javascript">\n';
    temp += 'function fldsubmit_'+controlName+'()\n';
    temp += '{\n';
    temp += 'document.aspnetForm' +'.'+ controlName+'.value = 2;\n';
    temp += strfmt("%1_%2_wfsubmit(\'SUBMIT\');\n",element.name(),webSession().getClientId());
    temp += '}\n';

    temp += '</SCRIPT>\n';
    createLink();
    webSession().writeTxt(temp);
    return ret;

сообствена у это userDefined элемента источником данных стоит edit метод на форме

edit WorkFlowAllMy editWorkFlowAllMy(boolean _set,WorkFlowAllMy _value)
{
    ;
    if (_set)
    {
        workFlowAllMy = _value;
    }
    return workFlowAllMy;
}

вроде бы все хорошо, но при выборе другого значения в этом combobox переход осуществляется на какую то новую страницу.
хочу чтобы перехода не было а страница просто обновилась по заданным значениям в combobox
saveViewState и loadViewState перекрыты








DAX 4.0 sp 2 MSSQL 2005

[Murlin]

Цитата:

Сообщение от Murlin

Доброго времени суток!
помогите пж-ста.

Все решилось просто. Во первых метод layout генерация кода в нем неверна
в должно быть так

public boolean layout()
{
    boolean         ret;
    str             temp;
    DictEnum        dictEnum;
    int             i;
    str     controlName;
    void createLink()
    {
        boolean         b;
        ;
        temp = temp + strfmt('<select size=1 id="%1" name="%1" onchange="fldsubmit_%1()">\n',controlName);
        dictEnum = new DictEnum(enumNum(WorkFlowAllMy));
        b = false;
        for (i=0;i<=dictEnum.values();i++)
        {
            if (dictEnum.index2Label(i))
            {
                if (workFlowAllMy == dictEnum.index2Value(i))
                {
                      temp = temp + strfmt("<option selected value=%1>%2</option>\n",dictEnum.index2Value(i),dictEnum.index2Label(i));
                }
                else
                     temp = temp + strfmt("<option value=%1>%2</option>\n",dictEnum.index2Value(i),dictEnum.index2Label(i));
            }
        }
        temp = temp + strfmt("</select>\n");
    }
    ;
    ret = super();
    controlName = webSession().createControlName(element,this);
    temp = '<SCRIPT language="javascript" type="text/javascript">\n';
    temp += 'function fldsubmit_'+controlName+'()\n';
    temp += '{\n';
    temp += strfmt("var val = document.getElementById('%1').value;\n",controlName);
    temp += strfmt("document.aspnetForm.%1.value = val;\n",controlName);
    temp += strfmt("%1_%2_wfsubmit('SUBMIT',%3,1);\n",element.name(),webSession().getClientId(),this.id());
    temp += '}\n';
    temp += '</SCRIPT>\n';
    createLink();
    webSession().writeTxt(temp);
    return ret;

т.е. основная ошибка тут

temp += strfmt("%1_%2_wfsubmit('SUBMIT',%3,1);\n",element.name(),webSession

т.е. сама процедура wfsubmit кроме комманды submit должна получать Id контрола формы
кроме того на userDefined контроле пришлось перекрыть метод setControl

public void setControl()
{
    str         s;
    int         i;
    ;
    super();
    s = WebSession().createControlName(element,this);
    workFlowAllMy = str2int(WebSession().getParm(s));
}