Программная разноска накладной со строками из нескольких заказов

[Ace of Database]

Привет всем!
Сто лет здесь не писал, но вот приспичило.
Вопрос: у меня есть два заказа.
Как программно обработать накладную с одной строкой из одного заказа, а второй строкой - из второго заказа?

Я умею обрабатывать накладные по одному заказу вот так:

void createInvoice(
                        transDate       _invoiceDate,
                        Num             _numberInvoice  = "",
                        SalesUpdate     _SalesUpdate = SalesUpdate::All
                      )
{
    SalesFormLetter_Facture_RU      salesFormLetter;
    int                                             parmEnum    = DocumentStatus::Invoice;
    SalesParmTable                         xSalesParmTable;
    SalesParmLine                           xSalesParmLine;
    num                                          _NumInvoice;
    salesTable                                updSalesTable;
;

    ttsbegin;

    salesFormLetter = SalesFormLetter::construct(parmEnum);

    SalesFormLetter.multiForm(true);

    SalesFormLetter.specQty(_SalesUpdate);

    if (_numberInvoice)
    {
        SalesFormLetter.setNumAndVoucher(_numberInvoice);
    }

    SalesFormLetter.printFormLetter(false);     //printInvoice

    if (parmEnum    == DocumentStatus::Facture_RU)
        SalesFormLetter.parmPrintFacture_RU(false);  //printFacture

    SalesFormLetter.update( salesTable,
                            _invoiceDate,//systemdateGet(),
                            SalesUpdate::DeliverNow,
                            AccountOrder::Auto,
                            NoYes::No,
                            NoYes::No,
                            _numberInvoice
                            );


    ttscommit;

}

[mazzy]

Цитата:

Сообщение от Ace of Database

Как программно обработать накладную с одной строкой из одного заказа, а второй строкой - из второго заказа?

Для начала сделайте это руками.

Расчеты с клиентами \ Периодические операции \ Обработка заказов \ Накладная.
Выберите несколько заказов в кнопке выбор.
Нажмите Ок.

Осталось только повторить аналогичные действия программно.

[Ace of Database]

И еще добавлю на всякий случай, что выбирать из обоих заказов надо не все строки, а только конкретные.

[mazzy]

Цитата:

Сообщение от Ace of Database

И еще добавлю на всякий случай, что выбирать из обоих заказов надо не все строки, а только конкретные.

Опять же, сделайте это руками


Расчеты с клиентами \ Периодические операции \ Обработка заказов \ Накладная.
Выберите несколько заказов в кнопке выбор.
+ Перейдите на закладку строки и укажите нужное вам количество в строках
Нажмите Ок.

Осталось только повторить аналогичные действия программно.

[glibs]

Если руками, то нагляднее выбрать несколько заказов в РК\Заказы на продажу и нажать Разноска\Накладная.

[mazzy]

Цитата:

Сообщение от glibs

Если руками, то нагляднее выбрать несколько заказов в РК\Заказы на продажу и нажать Разноска\Накладная.

Да, точно!

Я забыл указать пункт в инструкции

Расчеты с клиентами \ Периодические операции \ Обработка заказов \ Накладная.
Выберите несколько заказов в кнопке выбор.
Перейдите на закладку строки и укажите нужное вам количество в строках
+ Перейдите на закладку Прочее и включите Суммарная обработка (например по Счет на)
Нажмите Ок.

или как glibs говорит

[Ace of Database]

Получилось!

static void Job1(Args _args)
{
    SalesFormLetter letter=SalesFormLetter::construct(DocumentStatus::Invoice);
    SalesParmLine   parmLine;
    salesLine       salesLine;
    SalesParmTable  SalesParmTable;
    salesParmUpdate salesParmUpdate;
;
    ttsBegin;
    letter.transDate(systemDateGet());
    letter.multiForm(true);
    letter.specQty(SalesUpdate::All);
    letter.printFormLetter    (true);

    letter.createParmUpdate();
    select forupdate firstonly salesParmUpdate where
        salesParmUpdate.RecId == letter.salesParmUpdate().RecId;
    salesParmUpdate.SumBy = AccountOrder::Account;
    salesParmUpdate.update();
    letter.salesParmUpdate(salesParmUpdate);

    letter.initParameters(letter.salesParmUpdate(),
                        PrintOut::Current);  // Printout

    //1-й заказ
    letter.createParmTable(SalesParmTable, SalesTable::find("000151482"));
    SalesParmTable.DocumentDate = SalesTable::find("000151482").DeliveryDate;
    SalesParmTable.Transdate = SalesTable::find("000151482").DeliveryDate;
    SalesParmTable.insert();

    //2-й заказ
    SalesParmTable.clear();
    letter.createParmTable(SalesParmTable, SalesTable::find("000151483"));
    SalesParmTable.DocumentDate = SalesTable::find("000151482").DeliveryDate;
    SalesParmTable.Transdate = SalesTable::find("000151482").DeliveryDate;
    SalesParmTable.insert();

    //строка 1-го заказа
    select firstonly salesLine where salesLine.SalesId == "000151482" && salesLine.ItemId == "114014010";
    letter.createParmLine(salesLine);
    //строка 2-го заказа
    select firstonly salesLine where salesLine.SalesId == "000151483" && salesLine.ItemId == "11401401004";
    letter.createParmLine(salesLine);

    letter.run();
    ttscommit;
}

[Ace of Database]

Сделал метод, с помощью которого можно создавать одну накладную по нескольким строкам из разных заказов.

PHP код:

static void createOneInvoiceFromMultiSales(
            container       _conSales, //Перечень заказов (SalesId заказов)
            container       _conLines, //Перечень строк заказов (RecId строк заказов)
            TransDate       _invoiceDate, //Дата накладной
            TransDate       _documentDate, //Дата документа
            SalesUpdate     _specQty,
            AccountOrder    _sumBy
            )
{
    int             iSales, iLines;
    SalesFormLetter letter=SalesFormLetter::construct(DocumentStatus::Invoice);
    SalesParmLine   parmLine;
    SalesLine       salesLine;
    SalesParmTable  SalesParmTable;
    salesParmUpdate salesParmUpdate;
    SalesId         salesId;
    SalesTable      salesTable;
    RecId           recId;
    ;

    ttsBegin;
    letter.transDate(systemDateGet());
    letter.multiForm(true);
    letter.specQty(_specQty);
    letter.printFormLetter    (true);

    letter.createParmUpdate();
    select forupdate firstonly salesParmUpdate where
        salesParmUpdate.RecId == letter.salesParmUpdate().RecId;
    salesParmUpdate.SumBy = _sumBy;
    salesParmUpdate.update();
    letter.salesParmUpdate(salesParmUpdate);

    letter.initParameters(letter.salesParmUpdate(),
                        PrintOut::Current);  // Printout

    for (iSales = 1; iSales <= conlen(_conSales); iSales ++)
    {
        salesId = conpeek(_conSales, iSales);
        salesTable = salesTable::find(salesId);
        SalesParmTable.clear();
        letter.createParmTable(SalesParmTable, salesTable);
        SalesParmTable.DocumentDate = _documentDate;
        SalesParmTable.Transdate = _invoiceDate;
        SalesParmTable.insert();
    }

    for (iLines = 1; iLines <= conlen(_conLines); iLines ++)
    {
        recId = conpeek(_conLines, iLines);
        select firstonly salesLine where salesLine.RecId == recId;
        letter.createParmLine(salesLine);
    }

    letter.run();
    ttscommit;
} 


Вот так можно вызвать этот метод:

PHP код:

static void Job13(Args _args)
{
    Container   conSales, conLines;
    salesLine   salesLine;
    ;
    conSales = conins(conSales, 1, "000151482");
    conSales = conins(conSales, 2, "000151483");
    select firstonly salesLine where salesLine.SalesId == "000151482" && salesLine.ItemId == "114014010";
    conLines = conins(conLines, 1, salesLine.RecId);
    select firstonly salesLine where salesLine.SalesId == "000151483" && salesLine.ItemId == "11401401004";
    conLines = conins(conLines, 2, salesLine.RecId);
    MyClass::createOneInvoiceFromMultiSales(
        conSales, 
        conLines, 
        01\08\2007, 
        02\08\2007, 
        SalesUpdate::All, 
        AccountOrder::Account);
}