Выделенные строки на гриде -> QueryRun

[Eldar9x]

Как бы это покороче написать?

[Raven Melancholic]

Не очень понятен вопрос.
Если хотите сделать что-то вроде того, что из датасорса вытащить запрос, в котором кроме всех фильтров будет еще какой-то признак выделения строк и подсунуть такую конструкцию в queryRun, то, вроде бы такого нет.
Если нужно просто обработать строки, которые выделены, то нужно смотреть в сторону методов getFirst и getNext датасорса.
Например, в классе, в который передается курсор, независимо от того, выделено несколько строк или только одна, можно пользоваться чем-то вроде:

Цитата:

protected void initFromCaller(common _callerTable)
{
ShipmentsJournal_OVK locShipmentsJournal;
FormDataSource shipmentJournalDS;

shipmentJournalDS = _callerTable.dataSource();
for (locShipmentsJournal = (shipmentJournalDS && shipmentJournalDS.getFirst(1)) ? shipmentJournalDS.getFirst(1) : _callerTable;
locShipmentsJournal;
locShipmentsJournal = shipmentJournalDS ? shipmentJournalDS.getNext() : null)
{
// Тут обрабатываем переменную таблицы locShipmentsJournal

[Eldar9x]

Цитата:

Сообщение от Raven Melancholic

Не очень понятен вопрос.
Если хотите сделать что-то вроде того, что из датасорса вытащить запрос, в котором кроме всех фильтров будет еще какой-то признак выделения строк и подсунуть такую конструкцию в queryRun, то, вроде бы такого нет.
Если нужно просто обработать строки, которые выделены, то нужно смотреть в сторону методов getFirst и getNext датасорса.
Например, в классе, в который передается курсор, независимо от того, выделено несколько строк или только одна, можно пользоваться чем-то вроде:

нет, пробежать по выделенным строкам это понятно как. Имеется ввиду, каким образом получить QueryRun, который сделает точно такую же пробежку. Покороче. Использовать вышеприведенный код, собирая фильтр по RecId что ли?

[db]

Похоже я продолжаю упорно рекламировать одну и ту же фичу
Выборка произвольных записей одним запросом
Набираем RecId в Set любым способом (пример пробега по выделенным записям во втором сообщении) ну или вот готовый код:

public static Set dsGetMarked(FormDataSource _ds)
{
    Set     markedRecords = new Set(Types::Int64);
    Common  markedRecord;

    if (! _ds.anyMarked() && _ds.cursor())
    {
        markedRecords.add(_ds.cursor().RecId);
    }
    else
    {
        markedRecord = _ds.getFirst(true);
        while (markedRecord)
        {
            markedRecords.add(markedRecord.RecId);
            markedRecord = _ds.getNext();
        }
    }
    return markedRecords;
}

Смотрим пример использования класса RecordReferenceList_RU по ссылке выше. У данного класса есть возможность явно установить набор обрабатываемых записей setRecords().
Чуть измененный пример из исходной темы:

static void refList_TutorialSet(Args _args)
{
    RecordReferenceList_RU  refList = RecordReferenceList_RU::construct();
    RecordReference_RU      ref;
    InventTable             inventTable;
    int                     i;
    Set                     markedRecords = new Set(Types::Int64);
    Query                   query;
    QueryBuildDataSource    qbds;
    QueryRun                queryRun;
    ;

    setprefix("RecordReferenceList_RU");

    while select inventTable
    {
        markedRecords.add(inventTable.RecId);
        i++;
        if (i > 10)
        {
            break;
        }
    }
    refList.setRecords(markedRecords);
    refList.flush();

    info("Query");

    query = new Query();
    qbds  = query.addDataSource(tablenum(InventTable));
    refList.join(qbds);
    queryRun = new QueryRun(query);

    while (queryRun.next())
    {
        info(queryRun.get(tablenum(InventTable)).caption());
    }

    info("Select");

    while select inventTable
        join ref
            where ref.RefRecId == inventTable.RecId
               && ref.ParmId   == refList.getParmId()
    {
        info(inventTable.caption());
    }

    refList.cleanup();
}

плюсы/минусы/замечания описаны в исходной теме

[gl00mie]

Цитата:

Сообщение от Eldar9x

нет, пробежать по выделенным строкам это понятно как. Имеется ввиду, каким образом получить QueryRun, который сделает точно такую же пробежку.

А зачем? Есть тот же FormLetter::getFormRecords() (пишу по памяти, возможны очепятки).

[Eldar9x]

Цитата:

Сообщение от gl00mie

А зачем? Есть тот же FormLetter::getFormRecords() (пишу по памяти, возможны очепятки).

Мне нужен именно QueryRun, или Query, на худой конец.

[Raven Melancholic]

В любом случае, в QueryRun и в Query нет данных о выделенных строках, эти данные есть только в датасорсе. Так что пробежать по датасорсу все равно нужно, а вот что делать с этими данными, полученными при пробеге по датасорсу уже другой вопрос.
Один из вариантов это то, что предлагает db - воспользоваться классом RecordReferenceList_RU (если DAX2009, иначе сделать что-то подобное самому - там ничего особенно сложного нет).