Создание наследника EDT через Х++

[vesna]

Сразу оговорюсь, для чего (потому что сразу же вместо ответа каждый, пытающийся сделать что-то подобное, первым же "ответом" получал это самое "зачем"): Хочу сделать мастер создания справочников, чтобы освободить себя от нудной работы создания EDT, таблицы, полей, индексов и тд,тд..

Вопрос: ситуация такова, что при создании наследника EDT в Х++ свойства в АОТ родительского типа в свойства надо переносить руками, в отличии от создания того же вручную, где на сохраниение свойства родительского EDT выставляются системой.
Props = tableNode.AOTgetProperties() имеет вид просто строки, индивидуальной для каждого стандартного типа typebase EDT. А через DictType количество свойств для манипуляции ограничен (если я не пропустила в этом классе чего-то важного). Подскажите варианты заполнения свойств наследуемого EDT свойствами родительского EDT. Ну честное слово, не строку же Props обрабатывать..

[mazzy]

интересная задача...
вряд ли смогу сказать что-либо полезное по самому вопросу.
Думаю, что вам нужно рыть не в сторону DictType (он скорее на чтение), а в сторону treeNode... Хотя и не уверен.

но посмотрите сюда
http://www.axforum.info/forums/showt...&threadid=1437
http://www.axforum.info/forums/showt...&threadid=1850

а также сюда на работу с DictType (но не создание)
http://forum.mazzy.ru/index.php?showtopic=3668

[belugin]

http://erpkb.com/Axapta/Funkcija/setProperty

http://www.axaptapedia.com/index.php...ded_Data_Types

[vesna]

Решение найдено! Спасибо!
str val;
val = Global::findProperty(parentProps, "StringSize");
if (val)
Props = Global::setProperty(Props, "StringSize", val);

[mit]

указанным по ссылке belugin способом можно создать только стринговые EDT. Т.о. для каждого типа EDT необходимо написать свой метод, в котором при вставке в UtilIdElements нужно заполнить контейнер нужными свойствами.
Предлагаю свой вариант. Думаю, он проще.

PHP код:

static void Job1(Args _args)
{
UtilIdElements   uie;
XInfo            XInfo = new XInfo();
TreeNode         TNode;
TreeNode         DNode;
name             name = "MyInt";
int              id;
;

select maxof(id) from uie where uie.recordType == UtilElementType::ExtendedType && uie.utilLevel  == XInfo.currentAOLayer();
id =    uie.id;
id++;
select uie where uie.recordType == UtilElementType::ExtendedType && uie.name == "Integer";

uie.id = id;
uie.utilLevel  = XInfo.currentAOLayer( );
uie.recordType = UtilElementType::ExtendedType;
uie.name       = name;

uie.insert();
DNode = TreeNode::findNode("Data Dictionary\\\\Extended Data Types");
DNode.AOTrefresh();

TNode = TreeNode::findNode("Data Dictionary\\\\Extended Data Types\\\\"+name);
TNode.sysUtilDelete();
TNode.AOTsetProperties(setProperty(TNode.AOTgetProperties(), "Label"         , "Label" ));
TNode.AOTsetProperties(setProperty(TNode.AOTgetProperties(), "HelpText"      , "HelpText" ));
TNode.AOTsetProperties(setProperty(TNode.AOTgetProperties(), "DisplayLength" , "Auto" ));
TNode.AOTsetProperties(setProperty(TNode.AOTgetProperties(), "Alignment"     , "Auto" ));
TNode.AOTsetProperties(setProperty(TNode.AOTgetProperties(), "Extends"       , "Extends" ));

TNode.AOTsave();
DNode.AOTnewWindow();
TNode.AOTnewWindow();
} 


ps забыл что форум питается слешами :-)

[mit]

набор свойств можно дополнить. перечень можно скопировать их файла экспортированного элемента, или посмотреть в свойствах элемента.

[vesna]

То, что это Integer видно только из названия типа. А где в свойствах типа указывается, что я хочу создать Integer -тип ?
По умолчанию Аксапта создает String -тип.
Если я не права, то ткните меня носом в то место кода, где идет различие между созданием, скажем, Integer-типа от Enum-типа

[mit]

Ок, находим в UtilIdElements элемент с нужным типом. В нашем случае, этот элемент называется "Integer". Но легко можно и использовать и AmountNoDecimals. Вот и используем его контейнер. т.е. запись создается на основе имеющейся. Для Enum-типа анологично, можно взять хоть "AltAddressType", затем подчистить свойства - и имеем новый элемент Enum-типа.
Base Enums создаются несколько иначе.

PHP код:

//...
select maxof(id) from uie  where uie.recordType == UtilElementType::Enum && uie.utilLevel  == XInfo.currentAOLayer();

uie.id++;
uie.utilLevel  = XInfo.currentAOLayer( );
uie.recordType = UtilElementType::Enum;
uie.name       = _name;
uie.insert();

tNode = TreeNode::findNode("Data Dictionary\\\\Base Enums");
tNode.AOTrefresh();

tNode = TreeNode::findNode("Data Dictionary\\\\Base Enums\\\\"+_name);
//... 


ну и дальше добавляем елементы

ps да чтож он (форум) половину слешей съедает

[vesna]

А! Поняла идею! Буду пробовать. Спасибо

wow! девушка-программист

[vic_z]

Цитата:

Изначально опубликовано vesna
..Хочу сделать мастер создания справочников, чтобы освободить себя от нудной работы создания EDT, таблицы, полей, индексов и тд,тд..

После программного создания EDT, появиться еще одна проблемка - настроить Relation на EDT через код.

Я делал следующим образом.
Программно экспортировал существующий EDT (например AssetId). Далее в тексте xpo-файла производил замену текущего названия EDT на новое. После этого импортировал исправленный xpo-файл. Далее модифицировал свойства EDT через метод Global::setProperty().

Конечно этот метод можно назвать извращенным. Однако, более красивого способа, как можно добавить EDT's relation, я не нашел.

PHP код:

#aot
#AotExport
#File
#Properties
#define.DefaultStr_PatternName("AssetId")
#define.DefaultInt_PatternName("xRefPathRecId")
#define.EDTStartPos(61)
#define.test('123456789')
static void newEDT(str _name = "test", str _parentEDTName = "Num", boolean _withRelation = true)
{
    TreeNode   treeNode = treenode::findNode(#ExtendedDataTypesPath);
    TreeNode   patternNode;
    str        patternName;
    str        filename;
    TextBuffer textBuffer;
    int        exportId;
    DictType   dictType;
    ;

    if (treeNode.AOTfindChild(_name))
        throw error(strfmt("EDT %1 already exists", _name));

    if (_withRelation)
    {
        dictType = new DictType(treeNode.AOTfindChild(_parentEDTName).applObjectId());
        switch (dictType.baseType())
        {
            case Types::String :
                patternName = #DefaultStr_PatternName;
                break;
            case Types::Integer :
                patternName = #DefaultInt_PatternName;
                break;
            default:
                throw error(strfmt("Ðarent EDT %1 must be string or integer data type", _parentEDTName));
        }
    }
    else
    {
        patternName = _parentEDTName;
    }

    patternNode = treeNode.AOTfindChild(patternName);
    if (!patternNode)
        throw error(strfmt("Pattern EDT %1 does not exist", patternName));

    filename = Xinfo::directory(DirectoryType::Temp) + patternName + #xpo;

    patternNode.treeNodeExport(filename);

    textBuffer = new TextBuffer();
    textBuffer.fromFile(filename);
    textBuffer.replace(patternName, #test);
    textBuffer.replace(#test, _name);
    textBuffer.toFile(filename);

    exportId = infolog.startImport(filename, 0);

    infolog.importElement(exportId,
                          UtilFileType::Application,
                          UtilElementType::ExtendedType,
                          _name,
                          #EDTStartPos,
                          #impOk);

    infolog.endImport(exportId, 1);

    if (!treeNode.AOTfindChild(_name))
        throw error(strfmt("EDT %1 has not been created", _name));

} 


Теперь можно изменить программно Relation

PHP код:

    TreeNode         EDTNode = ....AOTfindChild(myNewEDT);
    TreeNode         parent = EDTNode.AOTfindChild(#PropertyRelations);
    TreeNode         relation;
    str              properties;
    ;
    parent = EDTNode.AOTfindChild(#PropertyRelations);
    relation = parent.AOTfirstChild();
    if (!relation)
    {
            throw error(strfmt("Relation of EDT %1 does not exist", EDTNode.toString()));
    }

    properties = relation.AOTgetProperties();
    properties = setProperty(properties, #PropertyTable, _tableName);
    properties = setProperty(properties, #PropertyRelatedfield, _relatedName);
    relation.AOTsetProperties(properties);
    EDTNode.AOTsave(); 


Надесь это как-нибудь поможет.

[vital-credo]

Я сделал всё проще. Это конечно не Ax 3.0, а AX 2009 (kernel 5.0.1000.52).
Вот пример функции:

public void changeRelation(str _tableName, str _relatedName, boolean _withThrow = true)
{
    TreeNode         relation;
    str              properties;
    ;

    relation = EDTNode.AOTfindChild(#PropertyRelations);
    if (!relation)
    {
        if (_withThrow)
            throw error("@SYS8500" + funcName());
        else
            return;
    }

    relation = relation.AOTaddSubNode(#NT_DBTYPENORMALREFERENCE);

    properties = relation.AOTgetProperties();
    properties = setProperty(properties, #PropertyTable, _tableName);
    properties = setProperty(properties, #PropertyRelatedfield, _relatedName);
    relation.AOTsetProperties(properties);

    EDTNode.AOTsave();
}

[Dark Light]

Цитата:

Сообщение от vital-credo

 relation = relation.AOTaddSubNode(#NT_DBTYPENORMALREFERENCE);

В AX2009 для этого есть метод AOTaddRelation.