Передать строку в контейнер

[Skolos]

Добрый день. возник вопрос. При преобразования строки в контейнер значение 000006 преобразуется в int64, и получается "Сотрудник,6". А мне нужно оставить его таким же в строковом формате. Как это правильно сделать?

    container Dimensions;
    str tmpDimensions = "Сотрудник,000006";
    ;
    Dimensions = str2con(strFmt(tmpDimensions, 1), ",");

[samolalex]

str2con_RU

[Skolos]

Цитата:

Сообщение от samolalex

str2con_RU

Спасибо)

[pedrozzz]

2012 R3 есть третий параметр в методе _convertNumericToInt64, в него передать false. На всякий случай весь метод целиком, вдруг у вас версия другая.

static container str2con(str _value, str 10 _sep = ',', boolean _convertNumericToInt64 = true)
{
    int         length = strLen(_value);
    int         separatorLength = strLen(_sep);
    int         i = 1;
    int         j = strScan(_value, _sep, 1, length);
    container   ret;
    void add2Ret(str _current)
    {
        if (_convertNumericToInt64 && (match('<:d+>', _current)))
        {
            ret += str2int64(_current);
        }
        else
        {
            ret += _current;
        }
    }

    while (j)
    {
        add2Ret(subStr(_value, i, j-i));
        i = j + separatorLength;
        j = strScan(_value, _sep, i, length);
    }
    add2Ret(subStr(_value, i, length-i+1));
    return ret;
}