Web разработка

[dtsymbal]

Помогите пожалуйста!

Нужно дать возможность пользователю через Web интерфейс Axapta сохранять на какой либо доступный для Axapta ресурс, будь то memo поле таблицы или каталог диска, файл со своего локального диска (любого иного ресурса доступного пользователю). Т.е. это должно быть похоже на прикрепление файлов к письму в любой почтовой службе.

Если у кого есть какой либо опыт в этом поделитесь пожалуйста.

Спасибо.

[mazzy]

посмотрите как реализован форум в корпоративном портале и прикрепление аттачментов к сообщениям.

[dtsymbal]

Если вам не составит труда уважаемый MAZZY напишите пожалуйста где в корпоративном портале есть такой функционал. Я начал с того что пытался найти что то подобное там, но тщетно.

Спасибо.

[EVGL]

Еще один пример - документооборот в портале. Активизируется автоматически, если есть доступ к документообороту. Ключевые классы: EPDocumentWeblet, EPSendDocument. Ключевая форма: EPDocuInfoEdit.

При этом код может быть примерно такой:

PHP код:

public void setControl()
{
    WebSession                      webSession = WebSession();
    COMVariant                      vars = new COMVariant();
    BinData                         binData;
    SysInetASPUploadIUploadedFile   fileitem = null;
    SysInetASPUploadUploadManager   um;

    FileName                        filename;
    FilePath                        filePath;

    int                             i;
    DocuRef                         docuRef;
    DocuActionFile                  docuActionFile;

    str endSlash(str _str)
    {
        return (strScan(_str, '\\',strLen(_str),-1)) ? _str : _str + '\\';
    }

    if (! webSession.getParm(webControlName))
        return;
    um = WebSession().aspUpload();
    if (! um)
        return;

    try
    {
        ttsbegin;

        for (i = 1; i <= um.Files().Count(); i++)
        {
            binData = new BinData();

            vars.int(i);
            fileitem = um.Files().Item( vars );
            if (! fileitem)
                continue;

            filename = fileItem.FileName();

            if (! fileDocuType)
            {
                fileDocuType = DocuType::find(ProblemWebParameters::find().FieleDocuTypeId);
            }
            if (! fileDocuType)
                throw error("@SYS22620");

            if (! filePath)
            {
                filePath = fileDocuType.ArchivePath ? fileDocuType.ArchivePath : DocuParameters::find().ArchivePath;
            }
            if (! filePath)
            {
                filePath = xInfo::directory(DirectoryType::Temp);
            }
            filePath = endSlash(filePath);

            binData.setVariant(fileitem.binary());
            if (! WinAPI::fileExists(filePath + fileName))
            {
                filename = filePath + fileName;
            }
            else
            {
                do
                {
                    filename = WinAPI::getTempFilename(filePath, "Att");
                    filename = subStr(filename, 1, strFind(filename, '.', strLen(filename), -255) - 1) + '.' +
                               conpeek(Docu::splitFilename(fileitem.FileName()), 2);
                }
                while (WinAPI::fileExists(filename));
            }
            if (! binData.saveFile(filename))
                throw error("@SYS69639" + ": " + WinAPI::formatMessage(WinAPI::getLastError()));

            docuActionFile = fileDocuType.docuAction();
            docuRef.clear();
            docuRef.initValue();
            docuRef.Name            = fileitem.FileName();
            docuRef.TypeId          = fileDocuType.TypeId;
            docuRef.RefCompanyId    = curExt();
            docuRef.Restriction     = DocuRestriction::Internal;
            docuRef.insert();

            docuActionFile.insertDocuValue(docuRef, filename);
            if (fileDocuType.filePlace == DocuFilePlace:://Database)
            {
                WinAPI::deleteFile(filename);
            }

            docuRefList.ins(docuRef);
        }
        ttscommit;
    }
    catch (Exception::Error)
    {
        this.abortSave();
    }
} 


[EVGL]

А вот что пишут другие спецы:

Цитата:

...

I found this in axapta technet because I need to upload files in
Enterpriseportal for import to salestable,salesline...
We are working with axapta 3.0 Sp3
It woks fine....

* first of all set the SubmitMethod-property of the design of the
webform to Multipart
* add a WebUserDefined control to the webform
* overwrite the layout-Methode and add following code:

webSession().writeTxt( this.label() + ': ' + 'input name="' +
this.name() + '" type="file"');

* overwrite the setControl-Methode and use following code:

WebSession ws = WebSession();
COMVariant vars = New COMVariant();
BinData BinData = New BinData();
SysInetASPUploadIUploadedFile fileitem = NULL;
SysInetASPUploadUploadManager um;
FileName strUploadFileName;

strUploadFileName = '... filename on server ...';
if (ws.getParm(this.name()))
{
um = WebSession().aspUpload();
vars.int( 1 );
fileitem = um.Files().Item( vars );
if( fileitem ){
BinData.setVariant( fileitem.binary() );
BinData.saveFile( strUploadFileName );
}
}

* add a WebButton and set the Command-property to OK


andY

[dtsymbal]

Спасибо за помощь.

А как вызвать диалог выбора файла в веб? Существуют ли в веб что то подобное Winapi::getOpenFileName?

[EVGL]

HTML-код 'input name= xxx type="file"' делает все за вас.

[dtsymbal]

Спасибо огромное!

Все получилось. Только в layout я написал так

webSession().writeTxt( '< input name="' + this.name() + '" type="file">');

[dtsymbal]

Ого.

В смысле input name="' + this.name() + '" type="file" находятся в <>