Синтаксис []

[Player1]

Доброго дня, странный затык, поискал в АОТе - примеров не нашёл. Собственно как передать массив в метод?
Если пытаться передать listNum[], то Синтаксическая ошибка.
Если просто lineNum, то Аргумент _listNum несовместим с требуемым типом.
Все компилируется если передать конкретный элемент listNum[1], но хочется-то все

static void JobArr(Args _args)
{
    Integer     listNum[];
    
    void method(Integer _listNum[])
    {
        Integer     newList[];
        ;

        newList = _listNum;
    }
    ;
    
    listNum[1] = 100;
    listNum[2] = 200;

    method(listNum[]);
}

[LETTO]

Да походу в динамический массив аксапта не умеет копировать.
Попробуйте указать
Integer newList[10];
и вызов
method(listNum);
может размер массива передавать первым параметром.

[Logger]

По-моему это нельзя сделать. Или я не знаю как.
Или использовать класс обертку, который и передавать.

[dech]

Аксапта не использует в параметрах передачу значений по ссылке, если только это не объект. Соответственно, о массивах в параметрах не может быть и речи. Поэтому есть два варианта: либо использовать классы коллекций, либо сделать массив локальной переменной класса. Использование .NET типов также не позволяет использовать массивы.

[Ace of Database]

Присваивать массивы нельзя, а передавать через параметры можно. Вот так:

static void Job1210(Args _args)
{
    Integer     listNum[];
    
    void method(Integer _listNum[])
    {
        ;

        info(strFmt("%1", _listNum[1]));
        info(strFmt("%1", _listNum[2]));
    }
    ;
    
    listNum[1] = 100;
    listNum[2] = 200;

    method(listNum);
}

Проверил в AX 2012 и AX 3 - работает одинаково. В CIL не проверял, но вроде пишут, что в CIL может сработать присваивание массивов, но вроде как будет работать как через указатели - изменение одного элемента в копии массива приведет к изменению того же эемента в исходном массиве. X++: X++ Arrays Behave Differently in .NET CIL, in Dynamics AX 2012

Т.е. newList = _listNum без CIL не вызовет ошибки компиляции, но не работает - массив newList останется пустой (я проверил). А внутри CIL скопируется ссылка на исходный массив (я не проверял).

[Ace of Database]

Но если размерность массива одинаковая, то можно не только передавать через параметры, то и присваивать:

static void Job1210(Args _args)
{
    int     listNum[2];

    void method(int _listNum[])
    {
        int newList[2];
        ;

        newList = _listNum;

        info(strFmt("%1", newList[1]));
        info(strFmt("%1", newList[2]));
    }
    ;

    listNum[1] = 100;
    listNum[2] = 200;

    method(listNum);
}

[Ace of Database]

Причем массив именно копируется при присваивании, а не передается по ссылке:

static void Job1210(Args _args)
{
    int     listNum[2];

    void method(int _listNum[])
    {
        int newList[2];
        ;

        newList = _listNum;

        newList[2] = 55;

        info(strFmt("%1", newList[1]));
        info(strFmt("%1", newList[2]));
        info(strFmt("%1", _listNum[2]));
    }
    ;

    listNum[1] = 100;
    listNum[2] = 200;

    method(listNum);
}

[S.Kuskov]

Конечно в Аксапте нативно поддерживается работа со статическими массивами. Вспомните Dimension. Его можно и присваивать и передавать в качестве параметра. Можно делать массивы полей в таблице (через соответствующие EDT). Такие массивы поддерживаются и в предложениях select и в group by.

[Товарищ ♂uatr]

Добрый день.
Почему не контейнер? Так же не любит менять размерность. Такой же быстрый доступ по индексу. Те же накладные расходы при передаче в виде параметра. С точки зрения расположения в оперативке - одно и тоже.

[Logger]

Цитата:

Сообщение от Товарищ ♂uatr

Такой же быстрый доступ по индексу.

Вроде в p-code всегда был медленный доступ по индексу.
Хотя возможно в последних версиях поменяли что-то.

[Товарищ ♂uatr]

Цитата:

Сообщение от Logger

Вроде в p-code всегда был медленный доступ по индексу.

Да, логично, погорячился, это не просто offset. Так понимаю container = обёртка над qlist. Сути особо не меняет, вопрос применения: динамика - list, статика - container.