Фильтрация в 2.5

[if_maks]

Добрый день всем.
Подскажите как можно наложить фильтр на отображаемую в форме таблицу, причем так что бы пользователь не мог его снять в Axapta ver. 2.5?
Пытаюсь использовать QueryBuildRange.status(RangeStatus::LOCKED); однако если вызвать 2-а раза контекстное меню --> "Найти..." и нажать ОК, не вводя значения, указаные выше ограничения слетают.
Спасибо!

[Wamr]

Искать и возобновлять ranges в ExecuteQuery перед super

[if_maks]

пробовал - та же история

[Wamr]

код - в студию

[if_maks]

Переменная qr инициализируется раньше в методе init() формы.
Метод setFormRange() вызывается после super() в методе init() соотвествующего dataSource
метод собственно накладывает ограничения на dataSource и запрещает их редактировать.

PHP код:

void setFormRange()
{
    int                     fieldNo;
    Query                   query;
    QueryBuildDataSource    queryBuildDataSource;
    QueryBuildRange         qbr;
    ;
    query = qr.query();   
    SalesTable_ds.query(query);
    queryBuildDataSource = query.dataSourceNo(1);
    for (fieldNo = 1; fieldNo <= queryBuildDataSource.rangeCount(); fieldNo++)
    {
        qbr = queryBuildDataSource.range(fieldNo);
        qbr.status(RangeStatus::LOCKED);
    }
} 


в executeQuery() перед super() вызываю этот же метод setFormRange()

[Wamr]

да... ну.... хм...
все пользовательские фильтры и сортировки хранятся в _ds.queryRun().query(...). То есть если Вы хотите их убрать, то менять нужно именно этот query.
С другой стороны, просто так брать и подменять запрос, на мой взгляд, слишком жестоко.

[if_maks]

да, если идти дальше действительно просто подменять query я не стану, т.к. нужно сохранить возможность накладывать пользовательские сортировки и фильтры с учетом фильтров хранящихся в qr.query().
но я застрял сразу с тем, что мои фильтры qr.query() - можно легко сбросить, а это уже против правил.
Может кто нибудь еще справился с подобной проблемой или просто знает как решить такую задачу или она не имеет решения в 2.5?
(нужно сделать аналог доступа на уровне записи как в это работает в 3.0)

[Wamr]

а в 3.0 такая же фигня - после двойного поиска фильтр можно менять
-------------
я же говорю, только проверив и восстановив все свои фильтры в executeQuery Вы сможете себя обезопасить

[if_maks]

Ну да, я про тот который настраивается в стандартном функционале и который отбирает записи как это... "на уровне ядра"

[if_maks]

Спасибо Wamr - натолкнули на мысль, однако действительно жестокость для аксапты неприемлема ...

PHP код:

void setFormRange()
{
    int                     rangeNo;
    Query                   query;
    QueryBuildDataSource    qbds;
    QueryBuildDataSource    qbdsUser;
    QueryBuildRange         qbr;
    QueryBuildRange         qbrUser;
    ;
//    if (ctrlSalesId.text())
    query = qr.query();
    qbdsUser = this.query().dataSourceName("SalesTable");
    qbds = query.dataSourceNo(1);
    for (rangeNo = 1; rangeNo <= qbds.rangeCount(); rangeNo++)
    {
        qbr = qbds.range(rangeNo);
        qbrUser = qbdsUser.findRange(fieldExt2Id(qbr.field()));
        if (!qbrUser)
            qbrUser = this.query().dataSourceName("SalesTable").addRange(fieldExt2Id(qbr.field()));
        qbrUser.value(qbr.value());
        qbrUser.status(RangeStatus::HIDDEN);
    }
} 


дело в шляпе.

[akvi]

Еще есть работа по настройке прав доступа на уровне записей в списках Axapta 2.5:
http://axapta.mazzy.ru/works/accessrecord/