Параметры и табличные переменные

[S.Kuskov]

Вопрос в том что понимать под "... и параметр изменяется в методе".

static void JobTestCommonParameter(Args _args)
{
    CustTable CustTable;

    void testMethod(CustTable _CustTable)
    {
        CustTable CustTable2;
        ;
        
        CustTable2.clear();
        _CustTable = CustTable2;
    }
    ;
    
    select CustTable;
    info(CustTable.AccountNum);
    testMethod(CustTable);
    info(CustTable.AccountNum);
}

Что такое табличная переменная? Это ссылка на объект Common.
В книге написано, что если передавать в метод ссылку на "временный" common, то ссылка (табличная переменная) будет передана по ссылке
Что такое изменение табличной переменной? Это присваивание ссылки на другой объект или обнуление ссылки

[maximka]

Цитата:

Сообщение от S.Kuskov

Вопрос в том что понимать под "... и параметр изменяется в методе". Что такое табличная переменная? Это ссылка на объект Common.
В книге написано, что если передавать в метод ссылку на "временный" common, то ссылка (табличная переменная) будет передана по ссылке

Ссылаясь на вас и немного подправив получается как раз то как я себе это понимаю:

static void JobTestCommonParameter(Args _args)
{
    CustTable custTable;

    void testMethod(CustTable _custTable)
    {
        _custTable.clear();
    }
 
    select custTable;
    info(custTable.AccountNum);
    testMethod(custTable);
    info(custTable.AccountNum);
}

Т.е. при изменении параметра, изменяется и исходная переменная.
Может, все-таки, я чего-то не догоняю?

[maximka]

Изменив первый джоб еще немного:

    void testMethod(CustTable _custTable)
    {
        CustTable custTable2;
    
        custTable2 = _custTable;
        custTable2.clear();
    }

Тот же результат...

[maximka]

В общем, смысл я понял И по вашему оно действительно работает как и сказано (для временной и обычной по разному), но я ориентировался на пример из книги:

void callByReference(TmpAccountSum _tmpAccountSum)
{
TmpAccountSum tmpAccountSum;
;
tmpAccountSum = _tmpAccountSum;
select firstonly tmpAccountSum order by accountNum desc;
{
info(tmpAccountSum.accountNum);
}
}

[S.Kuskov]

Цитата:

Сообщение от maximka

И по вашему оно действительно работает как и сказано (для временной и обычной по разному)

На самом деле у меня не получилось найти то действие которое бы изменяло/не изменяло параметр по разному для временных/постоянных таблиц. Так что я тоже в замешательстве. Что именно имелось в виду в книге не понятно

[maximka]

Цитата:

Сообщение от S.Kuskov

На самом деле у меня не получилось найти то действие которое бы изменяло/не изменяло параметр по разному для временных/постоянных таблиц. Так что я тоже в замешательстве. Что именно имелось в виду в книге не понятно

Создал временную таблицу и вот так работает как надо:

static void JobTestCommonParameter(Args _args)
{
    _TmpTable tmpTable;

    void testMethod(_TmpTable _tmpTableParm)
    {
        _tmpTableParm = null;
    }

    ttsbegin;
    tmpTable.selectForUpdate();
    tmpTable.NumberOf = 1;
    tmpTable.insert();
    ttscommit;
    select tmpTable;
    info(strfmt("%1",tmpTable.NumberOf));
    testMethod(tmpTable);
    info(strfmt("%1",tmpTable.NumberOf));
}

[S.Kuskov]

Цитата:

Сообщение от maximka

Создал временную таблицу и вот так работает как надо:

В AX2009 меняю свойство временности таблицы туда и обратно результат вашего примера остаётся прежним

[ice]

Цитата:

Сообщение от maximka

В общем, смысл я понял И по вашему оно действительно работает как и сказано (для временной и обычной по разному), но я ориентировался на пример из книги:

void callByReference(TmpAccountSum _tmpAccountSum)
{
TmpAccountSum tmpAccountSum;
;
tmpAccountSum = _tmpAccountSum;
select firstonly tmpAccountSum order by accountNum desc;
{
info(tmpAccountSum.accountNum);
}
}

этот пример очень хорошо демонстрирует передачу ссылки на временную таблицу, но при передаче с клиента на сервер (или наоборот) лучше использовать метод setTmpData():

tmpAccountSum.setTmpData(_tmpAccountSum);

[maximka]

Цитата:

Сообщение от ice

этот пример очень хорошо демонстрирует передачу ссылки на временную таблицу, но при передаче с клиента на сервер (или наоборот) лучше использовать метод setTmpData():

tmpAccountSum.setTmpData(_tmpAccountSum);

Так работает как и должно, ибо никаких ссылок не используется. Вопрос-то в том, что автор книги говорит о разном поведении системы для временной и обычной таблиц при передаче их через параметры. Чего я не смог повторить.

[AndyD]

Цитата:

Сообщение от ice

этот пример очень хорошо демонстрирует передачу ссылки на временную таблицу, но при передаче с клиента на сервер (или наоборот) лучше использовать метод setTmpData():

tmpAccountSum.setTmpData(_tmpAccountSum);

Этот пример демонстрирует передачу ссылки на табличную переменную

А вот использование setTmpData() - это как раз таки передача ссылки на временную таблицу. Причем, tmpAccountSum окажется на той же строне, что и _tmpAccountSum, но значения в этих переменных будут независимы (с привязкой к одной и той же временной таблице, естественно).

Передать данные из временной таблицы на другую строну можно только последовательным копированием и вставкой.